VBA – Declaração de Impressão (Print)

Descrição da Impressão (Print)

Grava dados formatados para exibição em um arquivo sequencial

Sintaxe de Print

Print #FileNumber, [OutputList]

A instrução Print contém 2 argumentos:

FileNumber: Qualquer número de arquivo válido.

OutputList: Opcional. Uma ou mais expressões numéricas ou expressões de cadeia de caracteres delimitadas por vírgulas para gravar em um arquivo.

Exemplos da Função Print do Excel VBA

Nome	Sobrenome	Idade	Gênero
Robert	Stepp	20	Masculino
Jennifer	Mariscal	33	Feminino
David	Romig	35	Masculino
Carmel	Ingram	26	Feminino

Para enviar o intervalo (“A1:D5”) em uma planilha como a da figura acima para um arquivo, você pode usar o seguinte código.

Sub Print_Exemplo()
    Dim strFolder As String
    Dim strFile As String
    Dim dlgFolder As FileDialog
    Dim rng As Range
    
    Set dlgFolder = Application.FileDialog(msoFileDialogFolderPicker)
    
    If dlgFolder.Show = True Then
        strFolder = dlgFolder.SelectedItems(1)
    Else
        Exit Sub
    End If
    
    Set rng = Range("A1:D5")
    
    'Print
    strFile = "Print_Saida.txt"
    ImprimirIntervaloParaArquivo strFolder & "\" & strFile, rng
End Sub

Sub ImprimirIntervaloParaArquivo(strFile As String, rng As Range)
    Dim row As Range, cell As Range
    Dim FileNumber As Integer
    FileNumber = FreeFile

    Open strFile For Output As #FileNumber
        For Each row In rng.Rows
            For Each cell In row.Cells
                If cell.Column = row.Cells.Count Then
                    Print #FileNumber, cell
                Else
                    Print #FileNumber, cell,
                End If
            Next cell
        Next row
    Close #FileNumber
End Sub

A saída para o arquivo “Print_Saida.txt”

Nome         Sobrenome     Idade          Gênero
Robert        Stepp          20           Masculino
Jennifer      Mariscal       33           Feminino
David         Romig          35           Masculino
Carmel        Ingram         26           Feminino