VBA 배열 지우기 – Erase 함수

이 튜토리얼에서는 VBA에서 배열을 지우는 방법을 설명합니다.

전체 배열 지우기

전체 배열을 지우려면 Erase 구문을 사용할 수 있습니다:

Erase arrExample

예제는 다음과 같습니다:

Sub ClearArray()
    '일반 배열을 선언합니다
    Dim arrExample(1 to 3) as String
 
    '배열 항목의 값을 채워줍니다
    arrExample(1) = "Shelly"
    arrExample(2) = "Steve"
    arrExample(3) = "Neema"
 
    '전체 배열을 지웁니다
    Erase arrExample

    '배열 값을 확인합니다
    MsgBox arrExample(1)
End Sub

배열 크기 조정하고 배열 항목 지우기

배열이 동적 배열인 경우(동적 배열은 크기를 조정할 수 없는 일반 배열과 달리 크기를 조정할 수 있는 배열입니다) ReDim 명령을 사용하여 배열의 크기를 조정하고 전체 값 배열을 지울 수 있습니다.

'전체 배열을 삭제하기 크기를 조정합니다
ReDim arrExample(1 To 4)

예제 코드는 다음과 같습니다:

Sub ClearArray2()
    '동적 배열을 선언합니다
    Dim arrExample() As String
    ReDim arrExample(1 To 3)
 
    '배열 값을 채워줍니다
    arrExample(1) = "Shelly"
    arrExample(2) = "Steve"
    arrExample(3) = "Neema"
 
    '배열을 삭제하고 크기를 조정합니다
    ReDim arrExample(1 To 4)
    
    '배열 값을 확인합니다
    MsgBox arrExample(1)
End Sub

배열의 일부 지우기

위에서 언급했듯이 ReDim 명령은 배열의 크기를 조정하고 배열의 모든 값을 지웁니다. ReDim Preserve를 사용하면 기존 값을 유지하면서 배열의 크기를 조정할 수 있습니다. 실제로 이 명령은 배열의 일부를 빠르게 지우는 데 사용할 수 있습니다.

'3번 인덱스 이후에 해당하는 값을 지웁니다
ReDim Preserve arrExample(1 To 2)

예제 코드는 다음과 같습니다:

Sub ClearArray3()
    '동적 배열을 선언합니다
    Dim arrExample() As String
    ReDim arrExample(1 To 3)
 
    '배열 값을 채워줍니다
    arrExample(1) = "Shelly"
    arrExample(2) = "Steve"
    arrExample(3) = "Neema"
 
    '3번 인덱스 이후의 값을 지웁니다
    ReDim Preserve arrExample(1 To 2)
    
    '처음 배열과 동일한 크기를 갖도록 크기를 재조정합니다
    ReDim Preserve arrExample(1 To 3)
    
    '배열 값을 확인합니다
    MsgBox arrExample(3)
End Sub

전체 배열 반복 – 값 재설정하기

Erase 또는 ReDim을 사용하여 배열 값을 지우는 대신 전체 배열을 반복하여 각 값을 재설정할 수 있습니다.