VBA – Zellen formatieren

In diesem Tutorial  zeigen wir Ihnen, wie Sie Zellen mit VBA formatieren können.

Zellen formatieren

Es gibt viele Formatierungseigenschaften, die für einen Zellenbereich wie diesen festgelegt werden können:

Sub ZellenFormatFestlegen()

    With Worksheets("Tabelle1").Range("B5:C7")
     .HorizontalAlignment = xlHAlignDistributed
     .AddIndent = True
     .Font.FontStyle = "Italic"
     .NumberFormat = "General"
     .Interior.Color = RGB(128, 100, 250)
    End With

End Sub

Schauen wir sie uns in alphabetischer Reihenfolge an:

AddIndent

Wenn Sie den Wert dieser Eigenschaft auf True setzen, wird der Text automatisch eingerückt, wenn die Textausrichtung in der Zelle entweder horizontal oder vertikal auf Gleichverteilung eingestellt ist (siehe HorizontalAlignment und VerticalAlignment).

With Worksheets("Tabelle1").Range("A1")
 .Orientation = xlVertical
 .VerticalAlignment = xlVAlignDistributed
 .AddIndent = True
End With

Umrandungen

Sie können das Randformat einer Zelle festlegen. Siehe hier für weitere Informationen über Rahmen.

Als Beispiel können Sie eine rote gestrichelte Linie um die Zelle B2 auf Tabelle1 wie folgt festlegen:

Worksheets("Tabelle1").Range("B2").BorderAround LineStyle:=xlDash, ColorIndex:=3

Schriftart

Sie können das Schriftformat der Zelle anpassen, indem Sie den Namen der Schriftart, den Stil, die Größe, die Farbe, das Hinzufügen von Unterstrichen oder Effekten (durchgestrichen, tief- oder hochgestellt) einstellen. Weitere Informationen über Zellenschriftarten finden Sie hier.

Hier sind einige Beispiele:

With Range("A1:C5").Font
 .Name = "Century" 
 .FontStyle = "Bold" 
 .Strikethrough = True
End With

FormulaHidden

Diese Eigenschaft liefert oder setzt einen Variantenwert, der angibt, ob die Formel ausgeblendet wird, wenn das Arbeitsblatt geschützt ist. Zum Beispiel:

 Worksheets("Tabelle1").Range("A1:B1").FormulaHidden = True

HorizontalAlignment

Diese Zellenformateigenschaft liefert oder setzt einen Variantenwert, der die horizontale Ausrichtung für das angegebene Objekt darstellt. Die zurückgegebenen oder gesetzten Konstanten können die folgenden sein: xlGeneral, xlCenter, xlDistributed, xlJustify, xlLeft, xlRight, xlFill, xlCenterAcrossSelection. Zum Beispiel:

Worksheets("Tabelle1").Range("D3").HorizontalAlignment = xlRight

IndentLevel

Diese liefert oder setzt einen ganzzahligen Wert zwischen 0 und 15, der die Einzugsebene für die Zelle oder den Bereich angibt.

Worksheets("Tabelle1").Range("A1").IndentLevel = 7

Interior

Sie können Informationen über das Zelleninnere (Color, ColorIndex, Pattern, PatternColor, PatternColorIndex, PatternThemeColor, PatternTintAndShade, ThemeColor, TintAndShade) folgendermaßen festlegen oder erhalten:

If Not Range("A1").Interior.ThemeColor = ThemeColorLight2 Then
   Range("A1").Interior.Pattern = xlPatternUp
End With

Locked

Diese Eigenschaft gibt True zurück, wenn die Zelle oder der Bereich gesperrt ist und False, wenn das Objekt geändert werden kann, wenn das Blatt geschützt ist oder Null, wenn der angegebene Bereich sowohl gesperrte als auch ungesperrte Zellen enthält. Sie kann auch zum Sperren oder Entsperren von Zellen verwendet werden.

In diesem Beispiel werden die Zellen A1:B2 auf Tabelle1 entsperrt, so dass sie geändert werden können, wenn das Blatt geschützt ist.

Worksheets("Tabelle1").Range("A1:B2").Locked = False 
Worksheets("Tabelle1").Protect

MergeCells

Setzen Sie diese Eigenschaft auf True, wenn Sie einen Bereich zusammenführen müssen. Sie erhält den Wert True, wenn der angegebene Bereich zusammengeführte Zellen enthält. Wenn Sie zum Beispiel den Bereich C5:D7 zusammenführen müssen, können Sie folgenden Code verwenden:

Worksheets("Tabelle1").Range("C5:D7").MergeCells = True

NumberFormat

Sie können das Zahlenformat innerhalb der Zelle(n) auf Standard, Zahl, Währung, Buchhaltung, Datum, Zeit, Prozent, Bruch, Wissenschaft, Text, Sonderformat und Benutzerdefiniert einstellen.

Hier sind die Beispiele für wissenschaftliche und prozentuale Zahlenformate:

Range("A1").NumberFormat = "0.00E+00"
Range("B1").NumberFormat = "0.00%"

NumberFormatLocal

Diese Eigenschaft liefert oder setzt einen Variantenwert, der den Formatcode für das Objekt als Zeichenfolge in der Benutzersprache darstellt.

Orientation

Mit dieser Eigenschaft können Sie die Textausrichtung innerhalb der Zelle(n) festlegen (oder erhalten). Ihr Wert kann eine der Konstanten xlDownward, xlHorizontal, xlUpward, xlVertical oder eine Ganzzahl von -90 bis 90 Grad sein.

Worksheets("Tabelle1").Range("A1").Orientation = -60

Parent

Dies ist eine schreibgeschützte Eigenschaft, die das übergeordnete Objekt eines angegebenen Objekts zurückgibt.

ShrinkToFit

Diese Eigenschaft liefert oder setzt einen Variantenwert, der angibt, ob der Text automatisch schrumpft, um in die verfügbare Spaltenbreite zu passen.

Worksheets("Tabelle1").Range("A1").ShrinkToFit = True

VerticalAlignment

Diese Zellenformateigenschaft liefert oder setzt einen Variantenwert, der die vertikale Ausrichtung für das angegebene Objekt darstellt. Die zurückgegebenen oder gesetzten Konstanten können die folgenden sein: xlCenter, xlDistributed, xlJustify, xlBottom, xlTop. Zum Beispiel:

Worksheets("Tabelle1").Range("A1").VerticalAlignment = xlTop

WrapText

Diese Eigenschaft gibt True zurück, wenn der Text in allen Zellen innerhalb des angegebenen Bereichs umbrochen ist, False, wenn der Text nicht in allen Zellen innerhalb des angegebenen Bereichs umbrochen ist oder Null, wenn der angegebene Bereich einige Zellen, die den Text umbrechen und andere, die dies nicht tun, enthält.

Wenn Sie zum Beispiel diesen Zellenbereich haben:

gibt der folgende Code Null im Direktfenster zurück:

?Worksheets("Tabelle1").Range("A1:B1").WrapText