Excel VBA: ColorIndex 코드 목록 & RGB Colors

VBA 색상 인덱스 코드 목록

VBA를 사용하여 셀의 Colorindex (또는 배경색)을 코딩할 때 어떤 정수가 어떤 색상과 같은지 알아두어야 합니다. 아래는 색상을 표시하고 해당 색상의 Colorindex를 나열하는 참조 그림입니다. 일명 VBA 색상 팔레트 입니다.

---

다음은 위 그림을 만들어주는 코드입니다:

Sub ColorRef()

Dim x As Integer

For x = 1 To 56
  If x < 29 Then
    Cells(x, 1).Interior.ColorIndex = x
    Cells(x, 2) = x
  Else
    Cells(x - 28, 3).Interior.ColorIndex = x
    Cells(x - 28, 4) = x
  End If
Next x

End Sub

VBA ColorIndex 예제

셀 배경색 설정하기

셀의 배경색을 설정합니다.

Range("A1").Interior.ColorIndex = 6

셀 글꼴 색상 설정하기

셀의 글꼴 색상을 설정합니다.

Range("A1").Font.ColorIndex = 5

셀의 테두리 색상 설정하기

셀의 테두리 색상을 설정합니다.

Range("A1").Borders.ColorIndex = 5

셀 배경색의 ColorIndex 값 가져오기

셀의 배경색을 가져와 Integer 변수에 할당합니다.

Dim col as Integer

col = Range("A1").Interior.ColorIndex

셀 배경색을 다른 셀의 색상으로 설정하기

셀 색상을 다른 셀 색상과 동일하게 설정합니다.

Range("A1").Interior.ColorIndex  = Range("B1").Interior.ColorIndex

VBA Color 속성

Excel/VBA의 ColorIndex 속성을 사용하는 대신 Color 속성을 사용할 수 있습니다. Color 속성에는 두 가지 입력 유형이 있습니다:

1. vbColor
2. RGB Colors

아래에서 이에 대해 설명하겠습니다:

VB Color

VB Color는 VBA에서 색상을 설정하는 가장 쉬운 방법입니다. 하지만 자유도가 가장 떨어지기도 합니다. vbColor를 사용하여 색상 코드를 설정하려면 아래 표를 사용해야 합니다:

그러나 위 그림에서 볼 수 있듯이 옵션이 매우 제한적입니다.

셀 배경색 설정하기

Range("A1").Interior.Color = vbYellow

셀 글꼴 색상 설정하기

Range("A1").Font.Color = vbBlue

셀의 테두리 색상 설정하기

Range("A1").Borders.Color = vbRed

셀 배경색을 다른 셀의 색상으로 설정하기

Range("A1").Interior.Color  = Range("B1").Interior.Color

RGB 색상

RGB는 빨강 녹색 파랑의 약자입니다. 이 세 가지 기본 색상을 조합하여 다른 색상을 만들 수 있습니다. RGB로 색상을 입력할 때는 각 색상 코드에 대해 0에서 255 사이의 값을 입력합니다.

다음은 예시입니다:

Range("A1").Interior.Color = RGB(255,255,0)

위에서는 빨간색 = 255(최대값), 녹색 = 255(최대값), 파란색 = 0(최소값)으로 설정했습니다. 이렇게 하면 셀 배경색이 노란색으로 설정됩니다.

다른 조합을 사용하면 셀 배경색을 보라색으로 설정할 수 있습니다:

Range("A1").Interior.Color = RGB(128,0,128)

원하는 색상의 RGB 코드를 찾을 수 있는 다양한 온라인 도구가 있습니다(여기를 클릭해주세요).

Access VBA의 ColorIndex 코드 목록 및 RGB 색상

Access는 폼을 사용하여 데이터를 표시합니다. ColorIndex 코드를 사용하여 Access 폼에서 개체의 배경색과 전경색을 프로그래밍 방식으로 변경할 수 있습니다.

Private Sub cmdSave_Click()
'레코드가 저장되면 save버튼의 배경색을 변경합니다
   DoCmd.RunCommand acCmdSaveRecord
   cmdSave.BackColor = vbGreen
End Sub