Excel VBA: Liste des Codes ColorIndex et couleurs RGB

Liste des Codes d’Indice de Couleur VBA

Lorsque l’on utilise VBA pour spécifier l’indice de couleur (ou la couleur de fond) d’une cellule, il est utile de savoir quel nombre entier correspond à quelle couleur. Vous trouverez ci-dessous une image de référence qui montre la couleur et énumère son indice de couleur respectif. Cette liste est aussi appelée Palette de couleurs VBA.

---

Voici le code pour en créer une vous-même, ou mettez simplement cette page en signet :

Sub RefCouleur()

Dim x As Integer

For x = 1 To 56
  If x < 29 Then
    Cells(x, 1).Interior.ColorIndex = x
    Cells(x, 2) = x
  Else
    Cells(x - 28, 3).Interior.ColorIndex = x
    Cells(x - 28, 4) = x
  End If
Next x

End Sub

Exemples ColorIndex VBA

Définir la Couleur d’Arrière-Plan d’une Cellule

Cet exemple définit la couleur d’arrière-plan de la cellule.

Range("A1").Interior.ColorIndex = 6

Définir la Couleur de Police de la Cellule

Cet exemple définit la couleur de police de la cellule.

Range("A1").Font.ColorIndex = 5

Définir la Couleur des Bordures de la Cellule

Cet exemple définit la couleur des bordures de la cellule.

Range("A1").Borders.ColorIndex = 5

Obtenir l’Indice de Couleur d’Arrière-Plan de la Cellule

Cet exemple récupère la couleur d’arrière-plan de la cellule et l’affecte à une variable de type Integer.

Dim col as Integer

col = Range("A1").Interior.ColorIndex

Définir la Couleur d’Arrière-Plan d’une Cellule à Celle d’une Autre Cellule

Cet exemple définit une couleur de cellule égale à la couleur d’une autre cellule.

Range("A1").Interior.ColorIndex = Range("B1").Interior.ColorIndex

Propriété VBA Color

Au lieu d’utiliser la propriété ColorIndex d’Excel / VBA, vous pouvez utiliser la propriété Color. La propriété Color prend en charge deux types d’entrée :

1. vbColor
2. Couleurs RGB

Nous les aborderons ci-dessous :

vbColor

Le moyen le plus simple pour définir des couleurs en VBA est d’utiliser vbColor. Cependant, c’est aussi la moins flexible. Pour définir un code couleur à l’aide de vbColor, utilisez le tableau ci-dessous :

Cependant, comme vous pouvez le voir dans le tableau, vos options sont extrêmement limitées.

Définir la Couleur d’Arrière-Plan d’une Cellule

Range("A1").Interior.Color = vbYellow

Définir la Couleur de Police des Cellules

Range("A1").Font.Color = vbBlue

Définir la Couleur des Bordures des Cellules

Range("A1").Borders.Color = vbRed

Définir la Couleur d’Arrière-Plan d’une Cellule à Partir de la Couleur d’une Autre Cellule

Range("A1").Interior.Color  = Range("B1").Interior.Color

Couleurs « RGB »

RGB signifie rouge, vert et bleu (« red, green, blue »). Il s’agit des trois couleurs primaires qui peuvent être combinées pour produire n’importe quelle autre couleur. Lorsque vous saisissez des couleurs au format RGB, entrez une valeur comprise entre 0 et 255 pour chaque code couleur.

Voici un exemple :

Range("A1").Interior.Color = RGB(255,255,0)

Ci-dessus, nous avons défini Rouge = 255 (valeur maximale), Vert = 255 (valeur maximale) et Bleu = 0 (valeur minimale). La couleur d’arrière-plan de la cellule est donc le jaune.

Au lieu de cela, nous pouvons définir la couleur de police de la cellule en violet :

Range("A1").Font.Color = RGB(128,0,128)

Il existe de nombreux outils en ligne pour trouver le code RGB de la couleur souhaitée (en voici un).

Liste des Codes ColorIndex et Couleurs RGB dans Access VBA

Access utilise des formulaires pour afficher des données. Vous pouvez utiliser les codes ColorIndex pour modifier par programme la couleur d’arrière-plan et la couleur d’avant-plan des objets dans vos formulaires Access.

Private Sub cmdSave_Click()
'change la couleur d'arrière plan du bouton de sauvegarde lorsque la table est enregistrée.
   DoCmd.RunCommand acCmdSaveRecord
   cmdSave.BackColor = vbGreen
End Sub