Formato Condicional Basado en el Resultado de BUSCARV – Excel y Google Sheets

Este tutorial mostrará varios ejemplos de cómo aplicar el Formato Condicional basado en el resultado de una Función BUSCARV en Excel y Google Sheets. Si tu versión de Excel soporta BUSCARX, te recomendamos que uses BUSCARX en su lugar.

 

Veamos un ejemplo en el que queremos aplicar un formato condicional basado en el resultado de una función BUSCARV.

 

Formato basado en la comparación BUSCARV

En primer lugar, aplicaremos un formato condicional a la tabla de Nombres e IDs de Estudiantes (col E-H) buscando las calificaciones de cada estudiante (Col B-C) y aplicando el Color de Relleno de Celda ROJO si sus calificaciones son inferiores a 72. El resultado se muestra aquí, pero seguiremos los pasos a continuación.

=BUSCARV($F3;$B$3:$C$7;2;FALSO)<72

 

Veamos cómo aplicar la fórmula anterior en formato condicional.

Aplicar formato condicional

1. Resalte el rango donde se aplicará el formato condicional.

 

2. En la cinta de opciones, vaya a la pestaña Inicio > Grupo de estilos > Formato condicional > Nueva regla.

 

3. En el menú emergente, seleccione Tipo de regla: Usar una fórmula para determinar las celdas a formatear.

 

4. En la barra de fórmulas, introduce nuestra fórmula.

 

5. Haz clic en Formato y define los ajustes de formato. En nuestro caso elegiremos un Color de Relleno ROJO. Haz clic en Aceptar.

 

6. Ahora haz clic en Aceptar y se aplicará la regla de formato condicional.

 

Ahora que sabemos cómo aplicar el formato condicional, vamos a ver la fórmula. Puede ser útil empezar introduciendo la(s) fórmula(s) de formato condicional en las celdas para probar que funcionan como se espera. Lo haremos a continuación.

Función BUSCARV

Primero, realizamos nuestro BUSCARV.

=BUSCARV($F3;$B$3:$C$7;2;FALSO)

 

Utilizamos $s para bloquear las referencias de las celdas. Esto es esencial para crear una fórmula que funcione para todas las filas.

Comparación Lógica

A continuación, los resultados se comparan con el criterio establecido.

=H3<72

 

El formato condicional cambiará el color de la celda para cualquier fila con VERDADERO. Combinando todas las fórmulas juntas se obtiene nuestra fórmula BUSCARV original:

=BUSCARV($F3;$B$3:$C$7;2;FALSO)<72

Formato Si el BUSCARV está en blanco

Fíjate que en el ejemplo anterior, un alumno no tenía puntuación. Podemos detectar y resaltar estas celdas añadiendo la función ESBLANCO:

=ESBLANCO(BUSCARV($F3;$B$3:$C$7;2;FALSO))

 

Así es como se evaluará la fórmula:

 

Formato Si el BUSCARV está dentro del rango de valores

Otro escenario común con BUSCARV es comprobar si el valor está dentro de un rango de valores dado. Para ello, podemos utilizar la función Y junto con BUSCARV:

=Y(BUSCARV($F3;$B$3:$C$7;2;FALSO)>=72;BUSCARV($F3;$B$3:$C$7;2;FALSO)<=74)

 

Repasemos la fórmula:

Límite inferior

Primero, comprobamos si la salida de nuestro BUSCARV es mayor o igual que un límite inferior dado (por ejemplo, 72).

=H3>=72

 

Límite superior

A continuación, comprobamos si ese mismo valor es menor o igual que el límite superior (por ejemplo, 74).

=H3<=74

 

Función Y

Por último, utilizamos la función Y para comprobar si ambas condiciones son VERDADERO.

=Y(I3;J3)

 

Combinando las fórmulas anteriores se obtiene nuestra fórmula original

=Y(BUSCARV($F3;$B$3:$C$7;2;FALSO)>=72;BUSCARV($F3;$B$3:$C$7;2;FALSO)<=74)

Formato Condicional – Múltiples Condiciones BUSCARV

Puede añadir fácilmente múltiples reglas de formato condicional:

 

Las reglas de formato condicional se aplican en orden (de arriba a abajo). Si se marca Detener si es verdad, entonces si se cumple esa condición no se prueban ni se aplican más reglas de formato. En nuestro ejemplo particular, el BU SCARVen blanco (por ejemplo, FILA 6) satisface dos condiciones, la roja (por ejemplo, <72) y la naranja (por ejemplo, ESBLANCO). Debido a que la regla ESBLANCO se aplica primero y se comprueba Detener si es verdad, la FILA 6 se resalta en NARANJA porque la condición ESBLANCO se cumple y las reglas posteriores no se comprueban.

 

Formato condicional basado en el resultado del BUSCARV en Google Sheets

Todas las fórmulas mencionadas anteriormente funcionan de la misma manera en Google Sheets, excepto si la tabla de búsqueda se encuentra en otra hoja. En este caso, tenemos que utilizar un rango con nombre o la función INDIRECTO para hacer referencia a rangos de otras hojas en el formato condicional.

=ESBLANCO(BUSCARV($C3;INDIRECTO("Scores!B3:C7");2;FALSO))

Estos son los pasos para aplicar el formato condicional en Google Sheets:

1. Resalte el rango y, a continuación, vaya a la pestaña Formato > Formato condicional

 

2. En la barra lateral, ve a «Reglas de formato» y selecciona «Fórmula personalizada es»

 

 

3. Introduce nuestra fórmula en la barra de fórmulas, y establece el estilo de formato y pulsa Hecho: