Número de Días entre Fechas en Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial le enseñará a calcular el número de días entre dos fechas en Excel y Google Sheets.
Restar fechas en Excel
En Excel, las fechas se almacenan como números de serie:
Esto permite restar fechas entre sí para calcular el número de días que hay entre ellas:
=C3-B3
Si la fecha fin es anterior a la fecha inicio, recibirá una respuesta negativa:
Si necesita el número absoluto de días entre las fechas, utilice la función ABS para devolver el valor absoluto:
=ABS(C3-B3)
Restar fechas con tiempos
En Excel, las horas se almacenan como valores decimales. Un valor decimal unido a un número de serie representa una Fecha y Hora:
Si usted resta una Fecha y Hora de otra Fecha y Hora. Recibirá una respuesta de Fecha y Hora (número de días, horas, minutos, segundos entre las dos fechas):
¿Notas que el número de días entre las fechas es *16*, pero el valor decimal es *0,51* debido a la diferencia horaria? Esto puede ser o no lo que quieres. En su lugar, podrías utilizar la función TRUNCAR para encontrar la diferencia entre las fechas:
=TRUNCAR(C3)-TRUNCAR(B3)
Pero también puedes utilizar las funciones DIAS o SIFECHA para un cálculo más sencillo…
Función DIAS – Calcular la diferencia entre fechas
La función DIAS calcula número de días entre fechas, ignorando las horas.
=DIAS(C3;B3)
La función DIAS devolverá valores negativos, por lo que puede utilizar la función ABS para el número absoluto de días entre fechas:
=ABS(DIAS(C3;B3))
Función DIAS360
La función DIAS360 funciona igual que la función DIAS, excepto que asume un año de 360 días donde cada mes tiene 30 días. Observe la diferencia en los cálculos:
=DIAS360(B3;C3)
Función SIFECHA – Número de días entre fechas
La función SIFECHA puede ser utilizada para calcular la diferencia de fechas en varias unidades de medida, incluyendo días, semanas, meses y años. Para utilizar la función SIFECHA para calcular el número de días entre fechas, establezca la unidad de medida como «d» para los días:
=SIFECHA(B3;C3;"d")
¡A diferencia de los otros métodos, la función SIFECHA no funcionará si la fecha de finalización es anterior a la fecha de inicio, sino que lanzará un error #NUM!
Para calcular la diferencia entre fechas con otras unidades de medida utilice esta tabla como referencia:
Calcular el número de días entre Hoy y otra fecha
Para calcular el número de días entre Hoy y otra fecha, utilice la misma lógica con la función HOY para una de las fechas. Esto calculará el número de días desde una fecha:
=DIAS(HOY();B3)
Esto calculará el número de días hasta una fecha:
=DIAS(B3;HOY())
Calcular los días laborables (hábiles) entre las fechas
La función DIAS.LAB le permite calcular el número de días laborables (de negocios) entre dos fechas:
=DIAS.LAB(B4;C4)
Por defecto, DIAS.LAB ignorará todos los días festivos. Sin embargo, puede utilizar un tercer argumento opcional para definir un rango de días festivos:
=DIAS.LAB(B4;C4;F3:F4)
Hojas de cálculo de Google – Días entre fechas
Todos los ejemplos anteriores funcionan exactamente igual en Google Sheets que en Excel.
