Insertar Nombre de Archivo – Fórmula de Excel
Descargar el Libro de Ejemplo
Este tutorial le enseñará cómo obtener un nombre de archivo utilizando una fórmula en Excel.
Obtener el nombre del archivo
En Excel no hay una función para obtener el nombre del archivo directamente. Sin embargo, la función CELDA devolverá la ruta del archivo, el nombre y la hoja. Usando las funciones de texto ENCONTRAR y EXTRAE, puedes extraer sólo el nombre del archivo.
=EXTRAE(CELDA("filename");ENCONTRAR("[";CELDA("filename"))+1; ENCONTRAR("]";
CELDA("filename"))-(ENCONTRAR("[";CELDA("filename"))+1))
Repasemos la fórmula.
Nombre del archivo, ruta y hoja de cálculo
Usamos la función CELDA para devolver la ruta del archivo, el nombre y la hoja introduciendo «filename» como tipo de información.
=CELDA("filename")
Encontrar la posición del nombre del archivo
Como se muestra arriba, la función CELDA devuelve la ruta del archivo, el nombre y la hoja de trabajo. No necesitamos la ruta y el nombre de la hoja de trabajo, así que utilizamos la función ENCONTRAR para determinar la posición del carácter inmediatamente anterior («[«) y posterior («]») al nombre del archivo.
Esta primera fórmula buscará «[«. Añadimos uno a la primera posición para empezar después del primer corchete («[«).
=ENCONTRAR("[";CELDA("filename"))+1
A continuación calculamos la posición del «]» para determinar dónde termina el nombre del archivo.
=ENCONTRAR("]";CELDA("filename"))
Toma la diferencia para encontrar la longitud del nombre del archivo:
Función EXTRAE
Ahora tenemos la posición inicial y la longitud del nombre del archivo. Introducimos estos resultados en la función EXTRAE para extraer el nombre del archivo a partir de la ruta, el nombre y la cadena de la hoja de cálculo.
=EXTRAE(B3;C3;E3)
Combinando estos pasos en una sola fórmula, obtenemos
=EXTRAE(CELDA("filename");ENCONTRAR("[";CELDA("filename"))+1; ENCONTRAR("]";
CELDA("filename"))-(ENCONTRAR("[";CELDA("filename"))+1))
