Suma Si la Celda Contiene un Texto Específico usando Comodines – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial demostrará cómo utilizar los comodines con la función SUMIFS para sumar los datos correspondientes a las celdas que contienen un texto específico en Excel y Google Sheets.
Suma Si el texto contiene
La función SUMAR.SI.CONJUNTO suma las filas de datos que cumplen ciertos criterios. Su sintaxis es:
Este ejemplo sumará todas los puntajes con un nombre de estado que contenga «Dakota» utilizando la función SUMAR.SI.CONJUNTO y el carácter comodín *.
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"*Dakota*")
El carácter * permite que cualquier número (incluido el cero) de otros caracteres ocupe su lugar. Este ejemplo encuentra todas las celdas que incluyen «Dakota». Esta búsqueda no distingue entre mayúsculas y minúsculas, por lo que «dakota» se considera lo mismo que «Dakota» o «DAKOTA».
Suma si el texto empieza por
El carácter * también se puede utilizar para buscar celdas que empiecen por el texto especificado:
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"New*")
New York, New Jersey y New México comienzan con «New» y, por tanto, se incluyen en la suma. Tenga en cuenta que, con el término de búsqueda «New*», la celda de texto debe empezar por «New»; no basta con que contenga esos caracteres.
Suma Si el texto termina en
Del mismo modo, podemos sumar todas las puntuaciones de los estados que terminan en «o» utilizando
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"*o")
New México y Ohio terminan en «o» y por lo tanto están incluidos en la suma.
Uso del carácter comodín ?
El carácter ? puede utilizarse para representar cualquier carácter en una cadena de texto. Este ejemplo busca todos los nombres de estados que empiezan por «New», seguidos de exactamente 7 caracteres (incluidos los espacios).
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"New???????")
New Jersey y New México cumplen estos criterios, pero New York no, ya que sólo hay 5 caracteres después de «New» en New York. Tenga en cuenta que los caracteres comodín * y ? pueden combinarse si es necesario para realizar comandos de búsqueda muy específicos.
El siguiente ejemplo busca los nombres de los estados que empiezan por «N» y contienen una «o» antes del último carácter de la cadena. Esto excluye a New México, que comienza con «N» pero no tiene una «o» antes del último carácter.
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"N*o?*")
Esta función es especialmente útil cuando se buscan códigos de producto, códigos postales o números de serie en los que la posición de cada carácter tiene un significado específico.
Uso del carácter ~ (tilde)
El carácter especial ~ (conocido como tilde) nos permite tratar los caracteres * o ? como si fueran simples valores de texto y no se comportan como comodines. En el siguiente ejemplo, necesitamos sumar el nivel de existencias cuando el nombre del producto coincide específicamente con el texto «Producto ?»
=SUMAR.SI.CONJUNTO(C3:C8;B3:B8;"Producto ~?")
El carácter ~ que precede inmediatamente a un * o a un ? lo convierte de nuevo en un valor de texto, por lo que el término de búsqueda «Producto ~?» se utiliza para encontrar una coincidencia de texto exacta con «Producto ?».
Combinación de comodines SUMAR.SI.CONJUNTO con referencias de celdas
Por lo general, no es una buena práctica codificar valores en las fórmulas. En su lugar, es más flexible utilizar celdas separadas para especificar los valores de nuestros términos de búsqueda. Para buscar si las celdas contienen el texto de la celda E3, podemos utilizar la función SUMAR.SI.CONJUNTO con una referencia de celda y * comodines:
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"*"&E3&"*")
Observe que el texto «Dakota» se ha sustituido por la referencia de celda &E3& y los caracteres * se han puesto entre comillas (» «). También se pueden combinar múltiples referencias de celdas y caracteres comodín.
Para encontrar los nombres de los estados que comienzan con el texto de la celda E3 y contienen el texto de la celda F3 seguido de al menos 1 carácter más, se puede utilizar la siguiente fórmula
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;E3&"*"&F3&"?*")
Bloqueo de las referencias de celda
Para que nuestras fórmulas sean más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:
=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;"*"&E3&"*")Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como las siguientes
=SUMAR.SI.CONJUNTO($C$3:$C$9;$B$3:$B$9;"*"&E3&"*")Lea nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.
Suma si la celda contiene un texto específico utilizando comodines en Google Sheets
Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.
