Sumar Si por Número de Semana – Excel y Google Sheets

Este tutorial demostrará cómo sumar datos correspondientes a números de semana específicos en Excel y Google Sheets.

 

Sumar Si por número de semana

Para «sumar si» por número de semana, utilizaremos la Función SUMAR.SI.CONJUNTO. Pero primero tenemos que añadir una columna auxiliar que contenga la función NUM.DE.SEMANA. La columna auxiliar del número de semana se calcula utilizando la función NUM.DE.SEMANA:

=NUM.DE.SEMANA(B3)

A continuación, utilizaremos la Función SUMAR.SI.CONJUNTO para sumar todas las Ventas que tienen lugar en un Número de Semana específico .

=SUMAR.SI.CONJUNTO(D3:D9;C3:C9;F3)

 

Suma por Número de Semana – Sin Columna Auxiliar

El método de la columna auxiliar es fácil de seguir, pero también puede replicar el cálculo en una sola fórmula utilizando la función SUMAPRODUCTO en combinación con la función NUM.DE.SEMANA para sumar el número total de ventas por número de semana.

=SUMAPRODUCTO(--(NUM.DE.SEMANA(B3:B9+0;1)=E3);C3:C9)

 

En este ejemplo, podemos utilizar la función SUMAPRODUCTO para realizar complicados cálculos de «suma si».

Veamos el ejemplo anterior. Esta es nuestra fórmula final:

=SUMAPRODUCTO(--(NUM.DE.SEMANA(B3:B9+0;1)=E3);C3:C9)

En primer lugar, la función SUMAPRODUCTO enumera el conjunto de valores de los rangos de celdas:

=(--(({"1/3/2020"; "1/6/2020"; "1/9/2020"; "1/12/2020"; "1/15/2020"; "1/18/2020"; "1/21/2020"}+0;1)=1); {4; 9; 1; 7; 6; 2; 5})

A continuación, la función NUM.DE.SEMANA calcula el número de semana de cada una de las fechas de venta.

La función NUM.DE.SEMANA no está diseñada para trabajar con valores de matrices, por lo que debemos añadir cero («+0») para que NUM.DE.SEMANA procese los valores correctamente.

=SUMAPRODUCTO(--({1;2;2;3;3;3;4}=1);{4;9;1;7;6;2;5})

Los valores de los números de semana iguales a 1 se cambian a valores VERDADERO.

=SUMAPRODUCTO(--({VERDADERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO});{4;9;1;7;6;2;5})

A continuación, los guiones dobles (–) convierten los valores VERDADERO y FALSO en unos  y ceros:

=SUMAPRODUCTO({1;0;0;0;0;0;0};{4;9;1;7;6;2;5})

A continuación, la función SUMAPRODUCTO multiplica cada par de entradas en las matrices para producir una matriz de Número de ventas que tienen un número de semana de 1:

=SUMAPRODUCTO({4; 0; 0; 0; 0; 0})

Por último, se suman los números de la matriz:

=4

Esta fórmula se repite para los demás valores posibles del número de semana. Puede encontrar más detalles sobre el uso de sentencias booleanas y el comando «–» en una función SUMAPRODUCTO aquí.

Bloqueo de las referencias de celdas

Para hacer nuestras fórmulas más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=SUMAPRODUCTO(--(NUM.DE.SEMANA(B3:B9+0;1)=E3);C3:C9)

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como esta

=SUMAPRODUCTO(--(NUM.DE.SEMANA($B$3:$B$9+0;1)=E3);$C$3:$C$9)

Lee nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.

 

Suma si por número de semana en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel. Sin embargo, la función NUM.DE.SEMANA es más flexible en Google Sheets que en Excel, y acepta entradas y salidas de matrices. Por lo tanto, la operación {Array}+0 en la fórmula NUM.DE.SEMAAN(B4:B10+0,1) no es necesaria.

La fórmula SUMAPRODUCTO completa se puede escribir en Google Sheets como

=SUMAPRODUCTO(--(NUM.DE.SEMANA(B4:B10;1)=E4);C4:C10)