Sumar Si por Día de la Semana – Excel y Google Sheets

Este tutorial mostrará cómo utilizar la función SUMAR.SI.CONJUNTO para sumar datos correspondientes a días específicos de la semana en Excel y Google Sheets.

 

 

Suma por Día de la Semana – Valores de Texto

En primer lugar, demostraremos cómo sumar datos correspondientes a Nombres específicos de Día de la Semana.

Podemos utilizar la Función SUMAR.SI.CONJUNTO, junto con una columna auxiliar que contenga la Función TEXTO para sumar todas las Ventas que tienen lugar en un Día de la Semana específico:

=SUMAR.SI.CONJUNTO($D$3:$D$9;$C$3:$C$9;F3)

 

En el ejemplo anterior, utilizamos la Función TEXTO para extraer el nombre del Día de la Semana de la Fecha de Venta:

=TEXTO(B3;"dddd")

 

A continuación, la Función SUMAR.SI.CONJUNTO utiliza esta columna auxiliar para producir la tabla resumen:

=SUMAR.SI.CONJUNTO($D$3:$D$9;$C$3:$C$9;F3)

 

Sumar Si por Día de la Semana – Usando DIASEM

También se pueden utilizar los números de los días de la semana. Para ello, la columna auxiliar de los datos de origen debe utilizar la Función DIASEM:

=DIASEM(B3)

 

El uso del valor numérico DIASEM en lugar del nombre del día de la semana puede proporcionarle opciones más flexibles para tareas posteriores de visualización de datos y funciones de resumen.

 

Suma de Datos por Día de la Semana – Sin Columna Auxiliar

El ejemplo anterior sumaba los datos por día de la semana utilizando una columna auxiliar. Para evitar la necesidad de una columna auxiliar, podemos utilizar la función SUMAPRODUCTO:

=SUMAPRODUCTO(--(DIASEM($B$3:$B$9)=E3);$C$3:$C$9)

 

En este caso, la función SUMAPRODUCTO realiza un complicado cálculo de «suma si». Veamos el ejemplo anterior.

Esta es nuestra fórmula final:

=SUMAPRODUCTO(--(DIASEM($B$3:$B$9)=E3);$C$3:$C$9)

Primero, la Función SUMAPRODUCTO evalúa el número de días de la semana de cada una de las Fechas de Venta y también lista la matriz de valores de la columna # de Ventas:

=SUMAPRODUCTO(--({6;2;5;1;4;7;3}=1);{4;9;1;7;6;2;5})

Usando la prueba lógica (=1), los números de día de la semana de 1 se cambian a VERDADERO, todos los demás son FALSOS:

=SUMAPRODUCTO(--({FALSO;FALSO;FALSO;VERDADERO;FALSO;FALSO;FALSO});{4;9;1;7;6;2;5})

A continuación, los guiones dobles (–) convierten los valores VERDADERO y FALSO en 1s y 0s:

=SUMAPRODUCTO({0;0;0;1;0;0;0};{4;9;1;7;6;2;5})

A continuación, la función SUMAPRODUCTO multiplica cada par de entradas de las matrices para producir una matriz de Número de ventas en las fechas de venta que coinciden con el Día de la semana 1:

=SUMAPRODUCTO({0; 0; 0; 7; 0; 0; 0})

Por último, se suman los números de la matriz:

=7

Más detalles sobre el uso de sentencias booleanas y el comando «–» en una Función SUMAPRODUCTO se pueden encontrar aquí

 

Bloqueo de Referencias de Celdas

Para hacer nuestras fórmulas más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=SUMAPRODUCTO(--(DIASEM(B3:B9)=E3);C3:C9)

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar de su archivo. En su lugar, debes utilizar referencias de celda bloqueadas como esta:

=SUMAPRODUCTO(--(DIASEM($B$3:$B$9)=E3);$C$3:$C$9)

Lee nuestro artículo sobre Bloqueo de referencias de celda para obtener más información.

 

Sumar SI por Día de la Semana en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.