Obtenir le Nom d’une Feuille de Calcul à Partir d’une Formule – Excel
Télécharger le Classeur Exemple
Ce tutoriel montre comment obtenir un nom de feuille de calcul à partir d’une formule dans Excel.
Obtenir le Nom de la Feuille de Calcul
Dans Excel, il n’existe pas de fonction permettant d’obtenir directement le nom d’une feuille de calcul. Mais vous pouvez obtenir le nom d’une feuille en utilisant VBA, ou vous pouvez utiliser les fonctions CELLULE, TROUVE, et STXT :
=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;31)
Examinons la formule ci-dessus.
Fonction CELLULE
Nous pouvons utiliser la fonction CELLULE pour renvoyer le chemin d’accès, le nom et la feuille du fichier en saisissant « nomfichier ».
=CELLULE("nomfichier")
Pour obtenir le nom de la feuille de calcul actuelle, vous pouvez utiliser la fonction avec ou sans l’argument optionnel de référence, en vous référant à n’importe quelle cellule de l’onglet actuel.
=CELLULE("nomfichier";A1)
Vous pouvez également obtenir des informations sur toute autre feuille de calcul en vous référant à une cellule de cette feuille.
=CELLULE("nomfichier";'Autre Feuille'!A1)
Fonction TROUVE
Comme indiqué ci-dessus, la fonction CELLULE renvoie le chemin d’accès au fichier, son nom et la feuille de calcul. Nous n’avons pas besoin du chemin ou du nom du classeur, nous devons donc isoler le nom de la feuille.
Utilisez d’abord la fonction TROUVE pour déterminer la position du caractère qui précède immédiatement le nom de la feuille (qui est toujours « ] »).
=TROUVE("]";B3)
Fonction STXT
Puisque nous connaissons la position du dernier caractère avant le nom de la feuille de calcul, nous pouvons maintenant utiliser la fonction STXT pour extraire les caractères qui suivent cette position. Le nom de notre feuille commence à la position trouvée ci-dessus + 1, mais nous ne connaissons pas la longueur du nom de la feuille. Cependant, nous connaissons la longueur maximale d’un nom de feuille de calcul (31), nous pouvons donc l’utiliser dans la fonction STXT:
=STXT(B3;C3+1;31)
En mettant tout cela ensemble, on obtient notre formule originale :
=STXT(CELLULE("nomfichier");TROUVE("]";CELLULE("nomfichier"))+1;31)
