Somme Si la Cellule Contient un Texte Spécifique en Utilisant des Caractères Génériques – Excel et Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

David Gagnon

Last updated on février 5, 2023

Ce tutoriel vous montrera comment utiliser les caractères génériques avec la fonction SOMME.SI.ENS pour additionner les données correspondant aux cellules qui contiennent un texte spécifique dans Excel et Google Sheets.

somme si cellule texte caracteres generiques fonction principale

Somme Si le Texte Contient

La fonction SOMME.SI.ENS additionne les lignes de données qui répondent à certains critères. Sa syntaxe est la suivante :

Cet exemple résume tous les pointages dont le nom d’État contient « Dakota » à l’aide de la fonction SOMME.SI.ENS et du caractère générique *.

=SOMME.SI.ENS(C3:C9;B3:B9;"*Dakota*")

somme si cellule texte caractere generiques contient

Le caractère * permet à n’importe quel nombre (y compris zéro) d’autres caractères de prendre sa place.

Cet exemple recherche toutes les cellules qui contiennent « Dakota ». Cette recherche n’est pas sensible à la casse, ainsi « dakota » est considéré comme identique à « Dakota » ou « DAKOTA ».

Somme Si le Texte Commence Par

Le caractère * peut également être utilisé pour rechercher les cellules qui commencent par le texte spécifié :

=SOMME.SI.ENS(C3:C9;B3:B9;"New*")

somme si cellule texte caractere generiques commence par

New York, New Jersey et New Mexico commencent par « New » et sont donc inclus dans la somme. Notez qu’avec le terme de recherche « New* », la cellule de texte doit commencer par « New » ; il ne suffit pas de contenir ces caractères.

Somme Si le Texte se Termine Par

De même, nous pouvons faire la somme de tous les pointages pour les États se terminant par « o » en utilisant la méthode suivante :

=SOMME.SI.ENS(C3:C9;B3:B9;"*o")

somme si cellule texte caractere generiques termine par

Le Nouveau-Mexique et l’Ohio se terminent par « o » et sont donc inclus dans la somme.

Utilisation du Caractère Générique ?

Le caractère ? peut être utilisé pour représenter n’importe quel caractère dans une chaîne de texte.

Cet exemple recherche tous les noms d’État commençant par « New », suivis d’exactement 7 caractères (espaces compris).

=SOMME.SI.ENS(C3:C9;B3:B9; "New???????")

somme si cellule texte caractere generiques un car

Le New Jersey et le Nouveau-Mexique répondent à ces critères, mais pas l’État de New York, car il n’y a que 5 caractères après « New » dans cet État.

Notez que les caractères génériques * et ? peuvent être combinés si nécessaire pour créer des commandes de recherche très spécifiques. L’exemple suivant recherche les noms d’État qui commencent par « N » et contiennent un « o » avant le dernier caractère de la chaîne. Cela exclut l’état New-Mexico, qui commence par « N » mais dont le dernier caractère n’est pas précédé d’un « o ».

=SOMME.SI.ENS(C3:C9;B3:B9;"N*o?*")

somme si cellule texte caractere generiques symboles combines

Cette fonctionnalité est particulièrement utile pour effectuer des recherches dans les codes de produits, les codes postaux ou les numéros de série, où la position de chaque caractère a une signification spécifique.

Utilisation du Caractère ~ (Tilde)

Le caractère spécial ~ (connu sous le nom de tilde) nous permet de traiter les caractères * ou ? comme s’il s’agissait de simples valeurs de texte et ne se comportent pas comme des caractères génériques.

Dans l’exemple ci-dessous, nous avons besoin d’additionner le niveau de stock lorsque le nom du produit correspond spécifiquement au texte « Produit ? » :

=SOMME.SI.ENS(C3:C8,B3:B8, "Produit ~?")

somme si cellule texte caractere generiques utilisation tilde 2

Le caractère ~ qui précède immédiatement un * ou un ? le transforme en valeur textuelle, de sorte que le terme de recherche « Produit ~ ? » est utilisé pour trouver une correspondance textuelle exacte avec « Produit ? ».

Combinaison de Caractères Génériques SOMME.SI.ENS avec des Références de Cellule

En général, il n’est pas recommandé de coder en dur des valeurs dans les formules. Il est plus souple d’utiliser des cellules distinctes pour spécifier les valeurs de nos termes de recherche.

Pour rechercher si les cellules contiennent le texte contenu dans la cellule E3, nous pouvons utiliser la fonction SOMME.SI.ENS avec une référence de cellule et des caractères génériques * :

=SOMME.SI.ENS(C3:C9;B3:B9;"*"&E3&"*")

somme si cellule texte caractere generiques contient reference

Notez que le texte « Dakota » a été remplacé par la référence de cellule &E3& et que les caractères * ont été mis entre guillemets ( » « ).

Il est également possible de combiner plusieurs références de cellules et des caractères génériques. Pour trouver les noms d’État qui commencent par le texte de la cellule E3 et contiennent le texte de la cellule F3 suivi d’au moins un caractère supplémentaire, vous pouvez utiliser la formule suivante :

=SOMME.SI.ENS(C3:C9;B3:B9;E3&"*"&F3&"?*")

somme si cellule texte caractere generiques combine reference

Verrouillage des Références de Cellules

Pour faciliter la lecture de nos formules, nous avons présenté les formules sans les références de cellule verrouillées :

=SOMME.SI.ENS(C3:C9;B3:B9;"*"&E3&"*")

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier. Vous devez plutôt utiliser des références de cellules verrouillées comme ceci :

=SOMME.SI.ENS($C$3:$C$9,$B$3:$B$9,"*"&E3&"*")

Lisez notre article sur le verrouillage des références de cellule pour en savoir plus.

Somme Si la Cellule Contient un Texte Spécifique en Utilisant des Caractères Génériques dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel. somme si cellule texte caracteres generiques google sheets