Listar Nomes de Planilhas com Fórmula – Excel

Este tutorial demonstra como listar os nomes das planilhas de uma pasta de trabalho com uma fórmula no Excel.

 

Listar nomes de planilhas usando intervalo nomeado e fórmula

Não há nenhuma função interna no Excel que possa listar todas as planilhas em uma pasta de trabalho. Em vez disso, você tem duas opções:

1. Usar uma macro VBA para listar todas as planilhas da pasta de trabalho
2. Criar uma fórmula para listar todas as planilhas

Se você quiser usar uma fórmula, siga estas etapas:

1. Crie um intervalo nomeado “BuscaPlanilhas”
2. Use uma fórmula para listar todos os nomes de planilhas.

Criar Intervalo Nomeado para os Nomes das Planilhas

Para criar um intervalo nomeado para os nomes das planilhas, na faixa de opções do Excel: Fórmulas > Gerenciador de nomes > Novo

Digite “BuscaPlanilhas” (este vai ser o nome da função que você está criando) na caixa de nome:

Na seção “Refere-se a” da caixa de diálogo, precisaremos escrever a fórmula:

=INFO.PASTA.TRABALHO(1) & T(AGORA())

Essa fórmula armazena os nomes de todas as planilhas na pasta de trabalho para o intervalo nomeado “BuscaPlanilhas”.

A função “INFO.PASTA.TRABALHO” é uma função de macro, portanto, sua pasta de trabalho deve ser salva como uma pasta de trabalho habilitada para macro (formato de arquivo: .xlsm) para que os nomes das planilhas sejam atualizados sempre que a pasta de trabalho for aberta.

Observação: Ao preencher a caixa de diálogo Editar nome, a pasta de trabalho deve ser selecionada como o escopo do intervalo de nomes.

Uso da Fórmula para Listar Nomes de Planilhas

Agora, usaremos uma fórmula para listar os nomes das planilhas. Precisaremos das funções ÍNDICE, EXT.TEXTO, PROCURAR e LINS:

=ÍNDICE(EXT.TEXTO(BuscaPlanilhas;PROCURAR("]";BuscaPlanilhas)+1;255);LINS($B$3:B3))

• A fórmula acima usa a matriz “BuscaPlanilhas” e exibe o nome de cada planilha com base em sua posição.
• As funções EXT.TEXTO e PROCURAR extraem os nomes das planilhas da matriz (removendo o nome da pasta de trabalho).
• Em seguida, as funções ÍNDICE e LINS exibem cada valor dessa matriz.
• Aqui, “Geral” é a primeira planilha das pastas de trabalho e “Limpeza” é a última.

Clique no link para obter mais informações sobre como as funções EXT.TEXTO e PROCURAR obtêm os nomes das planilhas.

Método Alternativo

Você também tem a opção de criar a lista de nomes de planilhas no Gerenciador de Nomes. Em vez de

=INFO.PASTA.TRABALHO(1) & T(AGORA())

defina seu campo “Refere-se a” como

=MUDAR(INFO.PASTA.TRABALHO(1);1;PROCURAR("]";INFO.PASTA.TRABALHO(1));"")

Agora não há necessidade de EXT.TEXTO PROCURAR e LINS em sua fórmula. Seu intervalo nomeado já é composto apenas de nomes de planilhas.

Use essa fórmula ÍNDICE mais simples para listar as planilhas:

=ÍNDICE(NomesPlanilhas;B3)