Soma se a célula contiver um texto específico usando caracteres curinga – Excel e Google Sheets
Este tutorial demonstrará como usar curingas com a função SOMASES para somar dados correspondentes a células que contêm texto específico no Excel e no Google Sheets
Soma se o Texto Contém
A função SOMASES soma as linhas de dados que atendem a determinados critérios. Sua sintaxe é:
Esse exemplo somará todos os Placares com um Nome de Estado que contenha “Dakota” usando a função SOMASES e o caractere curinga *.
=SOMASES(C3:C9;B3:B9;"*Dakota*")
O caractere * permite que qualquer número (inclusive zero) de outros caracteres tome seu lugar.
Este exemplo encontra todas as células que incluem “Dakota”. Essa pesquisa não diferencia maiúsculas de minúsculas, portanto, “dakota” é considerado o mesmo que “Dakota” ou “DAKOTA”.
Soma se o Texto Começar Com
O caractere * também pode ser usado para procurar células que comecem com o texto especificado:
=SOMASES(C3:C9;B3:B9;"New*")
New York, Nova Jersey e New Mexico começam com “New” e, portanto, estão incluídos na soma. Observe que, com o termo de pesquisa “New*”, a célula de texto deve começar com “New”; simplesmente conter esses caracteres não é suficiente.
Soma se o Texto Terminar Com
Da mesma forma, podemos somar todos os Placares dos Estados que terminam em “o” usando:
=SOMASES(C3:C9;B3:B9;"*o")
New Mexico e Ohio terminam com “o” e, portanto, estão incluídos na soma.
Usando o caractere curinga “?”
O caractere “?” pode ser usado para representar qualquer caractere único em uma string de texto.
Este exemplo encontra todos os Nomes de Estados que começam com “New”, seguidos de exatamente 7 caracteres (incluindo espaços).
=SOMASES(C3:C9;B3:B9;"New???????")
New Jersey e New Mexico atendem a esses critérios, mas New York não, pois há apenas 5 caracteres após “New” em New York.
Observe que os caracteres curinga * e ? podem ser combinados, se necessário, para criar comandos de pesquisa muito específicos. O próximo exemplo encontra Nomes de Estados que começam com “N” e contêm um “o” antes do último caractere da cadeia. Isso exclui o New Mexico; ele começa com “N”, mas não tem um “o” antes do último caractere.
=SOMASES(C3:C9;B3:B9;"N*o?*")
Essa funcionalidade é particularmente útil ao pesquisar códigos de produtos, códigos postais ou números de série em que a posição de cada caractere tem um significado específico.
Usando o Caractere ~ (til)
O caractere especial ~ (conhecido como til) nos permite tratar os caracteres * ou ? como se fossem valores de texto simples e não se comportam como curingas.
No exemplo abaixo, precisamos somar o Nível de Estoque quando o Nome do Produto corresponder especificamente ao texto ” Produto ?”:
=SOMASES(C3:C8;B3:B8;"Produto ~?")
O ~ imediatamente antes de um caractere * ou ? o transforma novamente em um valor de texto, de modo que o termo de pesquisa ” Produto ~?” é usado para encontrar uma correspondência de texto exata para “Produto ?”.
Combinação de Curingas SUMIFS com Referências de Células
Normalmente, não é uma boa prática codificar valores em fórmulas. Em vez disso, é mais flexível usar células separadas para especificar valores para nossos termos de pesquisa.
Para pesquisar se as células contêm o texto contido na célula E3, podemos usar a função SUMIFS com uma referência de célula e curingas *:
=SOMASES(C3:C9;B3:B9;"*"&E3&"*")
Observe que o texto “Dakota” foi substituído pela referência de célula &E3& e os caracteres * foram colocados entre aspas (” “).
Várias referências de células e caracteres curinga também podem ser combinados. Para encontrar Nomes de Estados que comecem com o texto na célula E3 e contenham o texto na célula F3 seguido de pelo menos mais um caractere, a seguinte fórmula pode ser usada:
=SOMASES(C3:C9;B3:B9;E3&"*"&F3&"?*")
Bloqueio de Referências de Células
Para facilitar a leitura de nossas fórmulas, mostramos as fórmulas sem referências de células bloqueadas:
=SOMASES(C3:C9;B3:B9;"*"&E3&"*")
Mas essas fórmulas não funcionarão corretamente quando forem copiadas e coladas em outro local do arquivo. Em vez disso, você deve usar referências de células bloqueadas como esta:
=SOMASES($C$3:$C$9;$B$3:$B$9;"*"&E3&"*")
Leia nosso artigo sobre bloqueio de Referências de Células para saber mais.
Soma se a Célula Contiver um Texto Específico Usando Caracteres Curinga no Google Sheets
Essas fórmulas funcionam exatamente da mesma forma no Google Sheets e no Excel.
