SUMMEWENN über mehrere Blätter – Excel & Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie die Funktionen SUMMENPRODUKT und SUMMEWENNS verwenden können, um Daten, die bestimmte Kriterien erfüllen, über mehrere Blätter in Excel und Google Sheets aufzusummieren.

Reguläre Summe über mehrere Blätter

Manchmal können sich Ihre Daten über mehrere Arbeitsblätter in einer Excel-Datei erstrecken. Dies ist häufig der Fall bei Daten, die in regelmäßigen Abständen erfasst werden. Jedes Blatt in einer Arbeitsmappe kann Daten für einen bestimmten Zeitraum enthalten. Wir möchten eine Formel, die die Daten in zwei oder mehr Blättern aufsummiert.

Mit der SUMME-Funktion können Sie ganz einfach Daten über mehrere Blätter hinweg aufsummieren, indem Sie eine 3D-Referenz verwenden:

=SUMME(Tabelle1:Tabelle2!A1)

Dies ist jedoch mit der Funktion SUMMEWENNS nicht möglich. Stattdessen müssen wir eine kompliziertere Formel verwenden.

SUMMEWENNS über mehrere Blätter

In diesem Beispiel wird die Anzahl der geplanten Lieferungen für jeden Kunden über mehrere Arbeitsblätter aufsummiert, die jeweils Daten für einen anderen Monat enthalten, indem die Funktionen SUMMEWENNS, SUMMENPRODUKT und INDIREKT verwendet werden:

=SUMMENPRODUKT(SUMMEWENNS(INDIREKT("'"&F3:F6&"'!"&"D3:D7");INDIREKT("'"&F3:F6&"'!"&"C3:C7");H3))

Gehen wir diese Formel einmal durch:

Schritt 1: Erstellen Sie eine SUMMEWENNS-Formel für nur ein Eingabeblatt:

Wir verwenden die SUMMEWENNS-Funktion, um die Anzahl der geplanten Lieferungen nach Kunde für ein einzelnes Eingabeblatt aufzusummieren:

=SUMMEWENNS(D3:D7;C3:C7;H3)

Schritt 2: Hinzufügen eines Blattverweises zur Formel

Wir behalten das Ergebnis der Formel bei, geben aber an, dass sich die Eingabedaten in dem Blatt mit dem Namen ‚Schritt 2‘befinden:

=SUMMEWENNS('Schritt 2'!D3:D7;'Schritt 2'!C3:C7;H3)

Schritt 3: Verschachtelung innerhalb einer SUMMENPRODUKT-Funktion

Um die Formel für die Durchführung von SUMMEWENNS-Berechnungen über mehrere Blätter vorzubereiten und dann die Ergebnisse zusammenzufassen, fügen wir eine SUMMENPRODUKT-Funktion um die Formel herum ein:

=SUMMENPRODUKT(SUMMEWENNS('Schritt 3'!D3:D7;'Schritt 3'!C3:C7;H3))

Die Verwendung der SUMMEWENNS-Funktion auf einem Blatt ergibt einen einzigen Wert. Über mehrere Blätter hinweg gibt die Funktion SUMMEWENNS ein Array von Werten aus (einen für jedes Arbeitsblatt). Wir verwenden die SUMMENPRODUKT-Funktion, um die Werte in diesem Array aufzusummieren.

Schritt 4: Ersetzen des Blattverweises durch eine Liste von Blattnamen

Wir möchten den Blattnamen-Teil der Formel durch eine Datenliste ersetzen, die die Werte enthält: Januar, Februar, März und April. Diese Liste wird in den Zellen F3:F6 gespeichert.

Die INDIREKT-Funktion sorgt dafür, dass die Textliste mit den Blattnamen als Teil eines gültigen Zellenbezugs in der SUMMEWENNS-Funktion behandelt wird.

=SUMMENPRODUKT(SUMMEWENNS(INDIREKT("'"&F3:F6&"'!"&"D3:D7");INDIREKT("'"&F3:F6&"'!"&"C3:C7");H3))

In dieser Formel wird die zuvor geschriebene Bereichsreferenz verwendet:

'Schritt 3'!D3:D7

Diese wird hierdurch ersetzt:

INDIREKT("'"&F3:F6&"'!"&"D3:D7")

Die Anführungszeichen erschweren die Lesbarkeit der Formel, daher wird sie hier mit zusätzlichen Leerzeichen dargestellt:

INDIREKT ( " ' " & F3:F6 & " ' ! " & "D3:D7" )

Die Verwendung dieser Art der Referenzierung einer Liste von Zellen ermöglicht es uns, auch Daten aus mehreren Blättern, die nicht dem Stil einer numerischen Liste folgen, zusammenzufassen. Eine Standard-3D-Referenz würde erfordern, dass die Blattnamen in der Form: Input1, Input2, Input3, usw. dargestellt werden, aber das obige Beispiel erlaubt es Ihnen, eine Liste mit beliebigen Blattnamen zu verwenden und diese in einer separaten Zelle zu referenzieren.

Zellenverweise sperren

Um unsere Formeln leichter lesbar zu machen, haben wir die Formeln ohne gesperrten Zellenbezüge dargestellt:

=SUMMENPRODUKT(SUMMEWENNS(INDIREKT("'"&F3:F6&"'!"&"D3:D7");INDIREKT("'"&F3:F6&"'!"&"C3:C7");H3))

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihrer Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenverweise wie die folgenden verwenden:

=SUMMENPRODUKT(SUMMEWENNS(INDIREKT("'"&$F$3:$F$6&"'!"&"D3:D7");INDIREKT("'"&$F$3:$F$6&"'!"&"C3:C7");H3))

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

SUMMEWENN über mehrere Blätter in Google Sheets

Die Verwendung der INDIREKT-Funktion, um auf eine Liste von Blättern in einer SUMMENPRODUKT- und SUMMEWENNS-Funktion zu verweisen, ist derzeit in Google Sheets nicht möglich.

Stattdessen können separate SUMMEWENNS-Berechnungen für jedes Eingabeblatt durchgeführt und die Ergebnisse aufaddiert werden:

=SUMMEWENNS(Januar!D3:D7;Januar!C3:C7;H3)
+SUMMEWENNS(Februar!D3:D7;Februar!C3:C7;H3)
+SUMMEWENNS(März!D3:D7;März!C3:C7;H3)
+SUMMEWENNS(April!D3:D7;April!C3:C7;H3)