BUSCARV y COINCIDIR Combinados – Excel & Google Sheets

Este tutorial demostrará cómo recuperar datos de múltiples columnas utilizando las funciones COINCIDIR y BUSCARV en Excel y Google Sheets.

 

 

¿Por qué debería combinar BUSCARV y COINCIDIR?

Tradicionalmente, cuando se utiliza la función BUSCARV, se introduce un número de índice de columna para determinar de qué columna se van a recuperar los datos. Esto presenta dos problemas:

• Si desea extraer valores de varias columnas, debe introducir manualmente el número de índice de la columna para cada columna
• Si inserta o elimina columnas, su número de índice de columna ya no será válido.

Para hacer que su función BUSCARV sea dinámica, puede encontrar el número de índice de la columna con la función COINCIDIR.

=BUSCARV(G3;B3:E5;COINCIDIR(H2;B2:E2;0);FALSO)

 

Veamos cómo funciona esta fórmula.

Función COINCIDIR

La función COINCIDIR devolverá el número de índice de la columna de la cabecera deseada. En el ejemplo siguiente, el número de índice de la columna «Edad» se calcula con la función COINCIDIR:

=COINCIDIR("Edad";B2:E2;0)

 

«Edad» es la segunda cabecera de columna, por lo que se devuelve 2.

Nota: El último argumento de la función COINCIDIR debe ser 0 para realizar una coincidencia exacta.

Función BUSCARV

Ahora, puede simplemente introducir el resultado de la función COINCIDIR en su función BUSCARV:

=BUSCARV(G3;B3:E5;H3;FALSO)

 

Reemplazando el argumento del índice de la columna con la Función COINCIDIR nos da nuestra fórmula original:

=BUSCARV(G3;B3:E5;COINCIDIR(H2;B2:E2;0);FALSO)

 

Inserción y eliminación de columnas

Ahora, cuando inserte o elimine columnas en el rango de datos, el resultado de su fórmula no cambiará.

 

En el ejemplo anterior, añadimos la columna Profesor al rango pero seguimos queriendo la Edad del alumno. La salida de la Función COINCIDIR identifica que «Edad» es ahora el 3er elemento en el rango del encabezado, y la Función BUSCARV utiliza el 3 como índice de la columna.

 

Bloqueando las Referencias de Celda

Para hacer nuestras fórmulas más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=BUSCARV(G3;B3:E5;COINCIDIR(H2;B2:E2;0);FALSO)

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como esta

=BUSCARV($G3;$B$3:$E$5;COINCIDIR(H$2;$B$2:$E$2;0);FALSO)

Lea nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.

 

BUSCARV y COINCIDIR Combinados en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.