Contar Si Múltiples Criterios en Excel y Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Dennis Madrid

Last updated on febrero 9, 2023

Descargar Libro de Ejemplo

Descargar el Libro de Ejemplo

Este tutorial muestra cómo «contar si» con múltiples criterios utilizando la función CONTAR.SI.CONJUNTO en Excel y Google Sheets. Si su versión de Excel no admite CONTAR.SI.CONJUNTO, también demostramos cómo utilizar la función SUMAPRODUCTO en su lugar.

Contar Si Conjunto Múltiples Criterios Master en Excel

Función CONTAR.SI.CONJUNTO

La función CONTAR.SI.CONJUNTO permite contar los valores que cumplen varios criterios. La estructura básica de la fórmula es

=CONTAR.SI.CONJUNTO(Rango 1, Condición 1, Rango 2, Condición 2)

Veamos un ejemplo. A continuación veremos una lista que contiene las calificaciones de los alumnos en inglés y matemáticas. Contemos todos los estudiantes con calificaciones superiores a 60 en Matemáticas.

=CONTAR.SI.CONJUNTO(C3:C12; ">"&60; D3:D12; "Matemáticas")

Contar Si Conjunto Múltiples Criterios Ej2 en Excel

En este caso, estamos probando dos criterios:

Si los resultados de la prueba son superiores a 60 (rango C3:C12)
Si la asignatura es «Matemáticas» (el rango es D3:D12)

A continuación, puede ver que hay 4 estudiantes que obtuvieron una puntuación superior a 60 en Matemáticas:

Contar Si Conjunto Múltiples Criterios Ej3 en Excel

Puede probar condiciones adicionales añadiendo otro rango y criterio. Por ejemplo, si quiere contar el número de estudiantes que obtuvieron una puntuación entre 60 y 80 en Matemáticas, utilizaría este criterio:

Si los resultados del test son superiores a 60
Si los resultados de la prueba son inferiores a 80
Si la asignatura es «Matemáticas»

Aquí están las secciones resaltadas donde se prueban estos ejemplos.

Condiciones Función Contar Si Conjunto en Excel

El resultado, en este caso, es 3.

=CONTAR.SI.CONJUNTO(C3:C13;">" & 60;C3:C13;"<"&80;D3:D13;"Matemáticas")

Contar Si Conjunto Múltiples Criterios Ej4 en Excel

Función SUMAPRODUCTO

Si no tiene acceso a CONTAR.SI.CONJUNTO, puede realizar la misma tarea con la función SUMAPRODUCTO. La Función SUMAPRODUCTO abre un mundo de posibilidades con fórmulas complejas (ver Tutorial de SUMAPRODUCTO). Por lo tanto, aunque tenga acceso a la función CONTAR.SI.CONJUNTO, puede empezar a familiarizarse con esta poderosa función. Su sintaxis es

=SUMAPRODUCTO(Rango 1=Condición 1*Rango 2=Condición 2)

Utilizando el mismo ejemplo anterior, para contar todos los estudiantes con puntuaciones superiores a 60 en la asignatura «Matemáticas», puede utilizar esta fórmula

=SUMAPRODUCTO((C3:C13>60)*(D3:D13="Matemáticas"))

Condiciones Función Sumaproducto en Excel

La primera condición comprueba qué valores de ese rango son mayores de 60, y la segunda comprueba qué valores de ese rango son iguales a «Matemáticas». Esto nos da una matriz de valores booleanos de 1 (VERDADERO) o 0 (FALSO):

=SUMAPRODUCTO((C3:C13>60)*(D3:D13="Matemáticas"))

=SUMAPRODUCTO(({82;62;71;76;95;45;55;56;72;85;86}>60)*
({"Matemáticas";"Matemáticas";"Inglés";"Matemáticas";"Inglés";"Matemáticas";"Inglés";"Matemáticas";"Matemáticas";"Inglés";"Inglés"}="Matemáticas"))

=SUMAPRODUCTO({VERDADERO;VERDADERO;VERDADERO;VERDADERO;VERDADERO;FALSO;FALSO;FALSO;VERDADERO;VERDADERO;VERDADERO}*
{VERDADERO;VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO;VERDADERO;FALSO;FALSO})

=SUMAPRODUCTO({1;1;0;1;0;0;0;0;1;0;0})

Finalmente, tenemos el resultado de 4.

A continuación, la función SUMAPRODUCTO suma todos los elementos del array, lo que nos da el recuento de alumnos que han sacado alrededor de 60 en matemáticas.

Función Sumaproducto Mayores a 60 en Matemáticas