Encontrar la Última Fila con Datos – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial demostrará cómo encontrar la última fila no en blanco en un conjunto de datos en Excel y Google Sheets.
Encontrar la última fila con datos
A menudo es útil saber en qué fila terminan tus datos. Si tu rango tiene o puede tener celdas en blanco, puedes encontrar la última fila que no esté en blanco utilizando uno de los métodos siguientes.
Método Universal
El primer método utiliza las funciones FILA y MAX y puede ser utilizado con cualquier tipo de datos:
=MAX((B:B<>"")*FILA((B:B)))
Analicemos esta fórmula. Empezamos utilizando una prueba lógica en la columna de datos. Nuestra fórmula examina toda la columna (B:B) y da como resultado VERDADERO para las celdas no vacías y FALSO para las celdas vacías.
=B:B<>""
La función FILA produce el número de fila de una celda dada. Si no le damos una entrada de celda específica, da el número de fila de la celda en la que se encuentra.
=FILA()
Multiplicando cada número de fila por los correspondientes valores VERDADERO(= 1) o FALSO (= 0), devuelve el número de fila de una celda poblada, y cero para una celda vacía.
=E3*F3
La función MAX da el máximo de un conjunto de números. En este ejemplo, como todas las celdas vacías producen un valor cero, el máximo es el número de fila más alto.
=MAX(G3:G12)
Combinando estos pasos obtenemos nuestra fórmula original:
=MAX((B:B<>"")*FILA((B:B)))
Ten en cuenta que se trata de una fórmula de rango, por lo que si utilizas Excel 2019 o anterior, tienes que pulsar CTRL + SHIFT + ENTER para activarla.
Método para el rango de texto
Si tu rango (no continuo) sólo contiene valores de texto y celdas en blanco, puedes utilizar una fórmula menos complicada que contenga las Funciones REPETIR y COINCIDIR:
=COINCIDIR(REPETIR("z",50),B:B)
Veamos cómo funciona esta fórmula.
Función REPETIR
La función REPETIR repite una cadena de texto un número determinado de veces. Para este ejemplo, podemos utilizarla para crear una cadena de texto que sería la última en cualquier lista ordenada alfabéticamente. Si repetimos «z» 50 veces, esto debería funcionar para casi cualquier columna de datos de texto; ninguna entrada vendría antes de «zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz» alfabéticamente.
=REPETIR("z",50)
Función COINCIDIR
La función COINCIDIR encuentra un valor de búsqueda dado en un array.
Realizamos una búsqueda en toda la columna de datos para nuestra cadena de texto de 50 z. Al omitir la entrada del tipo de coincidencia en la función MATCH, se le indica que busque una coincidencia aproximada en lugar de una exacta.
=COINCIDIR(REPETIR("z",50),B:B)
La Función COINCIDIR busca en la Columna B y busca nuestra cadena de texto de 50 «z». Como no la encuentra, la fórmula devuelve la posición de la última celda que no está en blanco. Esta celda contiene el último valor de la matriz de búsqueda que es menor (o igual) que el valor de búsqueda.
Ten en cuenta que esta fórmula sólo funciona cuando tu rango contiene exclusivamente texto y celdas en blanco (o al menos el valor de la última celda no es numérico).
Buscar la última fila con datos en Google Sheets
Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.
