Volver a la Lista de Fórmulas de Excel

Suma Si No Está en Blanco – Excel y Google Sheets

Descargar Libro de Ejemplo

Descargar el Libro de Ejemplo

Este tutorial demostrará cómo utilizar la función SUMAR.SI.CONJUNTO para sumar datos relacionados con celdas no vacías o en blanco en Excel y Google Sheets.

suma si no esta en blanco

 

Suma si no está en blanco

En primer lugar, demostraremos cómo sumar los datos relativos a las celdas que no están en blanco. Podemos utilizar la función SUMAR.SI.CONJUNTO para sumar todas las puntuaciones de los jugadores con nombres que no están en blanco utilizando los criterios («<>»).

=SUMAR.SI.CONJUNTO(C3:C8;B3:B8;"<>")

suma si celda no vacía

 

Tratando los espacios como celdas en blanco – Con la columna auxiliar

Debes tener cuidado cuando interactúes con celdas en blanco en Excel. Las celdas pueden aparecer en blanco, pero Excel no las tratará como tales. Esto puede ocurrir si la celda contiene espacios, saltos de línea u otros caracteres invisibles. Este es un problema común cuando se importan datos a Excel desde otras fuentes. Si necesitamos tratar cualquier celda que sólo contenga espacios de la misma manera que si estuviera en blanco, entonces la fórmula del ejemplo anterior no funcionará. Fíjate en que la fórmula SUMIFS no considera la celda B9 de abajo (» «) como en blanco:

=SUMAR.SI.CONJUNTO(D3:D9;B3:B9;"<>")

suma si celda no vacía error

 

Para tratar una celda que sólo contiene espacios como si fuera una celda en blanco, podemos añadir una columna de ayuda utilizando las funciones LARGO y ESPACIOS. La función ESPACIOS elimina los espacios extra de la celda. La función LARGO cuenta el número de caracteres restantes. Si el conteo es 0, entonces la celda «recortada» está en blanco.

=LARGO(ESPACIOS(B3))

Funciones largo espacios

 

Ahora utilice la Función SUMAR.SI.CONJUNTO para sumar si el conteo > 0.

=SUMAR.SI.CONJUNTO(E3:E9;D3:D9;">0")

sumar si conjunto no vacías aux

 

La columna auxiliar es fácil de crear y fácil de leer, pero es posible que desee tener una sola fórmula para realizar la tarea. Esto se trata en la siguiente sección.

Tratando los espacios como celdas en blanco – Sin columna auxiliar

Para lograr todo esto con una sola fórmula, podemos utilizar la función SUMAPRODUCTO en combinación con las funciones LARGO y ESPACIOS.

=SUMAPRODUCTO(--(LARGO(ESPACIOS(B3:B9))>0);D3:D9)

sumar si conjunto sumaproducto

 

Veamos la fórmula. Primero, la función SUMPRODUCTO lee los valores de las celdas:

=SUMAPRODUCTO(--(LARGO(ESPACIOS({"A";"B";0;"C";0;"XX";"   "}))>0);{25;10;15;5;8;17;50})

A continuación, la función ESPACIOS elimina los espacios iniciales y finales de los nombres de los jugadores :

=SUMAPRODUCTO(--(LARGO({"A";"B";"";"C";"";"XX";""})>0);{25;10;15;5;8;17;50})

La función LARGO calcula las longitudes de los nombres de los jugadores recortados:

=SUMAPRODUCTO(--({1;1;0;1;0;2;0}>0);{25;10;15;5;8;17;50})

Con la prueba lógica (>0), cualquier nombre de jugador recortado con más de 0 caracteres se cambia a VERDADERO:

=SUMAPRODUCTO(--({VERDADERO;VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO;FALSO});{25;10;15;5;8;17;50})

A continuación, los guiones dobles (–) convierten los valores VERDADERO y FALSO en 1s y 0s:

=SUMAPRODUCTO({1;1;0;1;0;1;0};{25;10;15;5;8;17;50})

A continuación, la función SUMAPRODUCTO multiplica cada par de entradas en las matrices para producir una matriz de puntuaciones sólo para los nombres de los jugadores que no están en blanco o que no están formados sólo por espacios:

=SUMAPRODUCTO({25;10;0;5;0;17;0})

Por último, se suman los números de la matriz

=57

Puedes encontrar más detalles sobre el uso de sentencias booleanas y el comando «–» en una función SUMAPRODUCTO aquí

Suma Si no Está en Blanco en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.

suma si no esta en blanco gsheets

Excel Practice Worksheet

practice excel worksheet

Practice Excel functions and formulas with our 100% free practice worksheets!

  • Automatically Graded Exercises
  • Learn Excel, Inside Excel!

Free Download

Volver a la Lista de Fórmulas de Excel