Volver a la Lista de Fórmulas de Excel

Suma Si está en Blanco – Excel y Google Sheets

Descargar Libro de Ejemplo

Descargar el Libro de Ejemplo

Este tutorial demostrará cómo utilizar la función SUMAR.SI.CONJUNTO para sumar los datos correspondientes a las celdas en blanco o vacías en Excel y Google Sheets.

sumar si esta en blanco

 

Suma Si está en blanco

Primero, demostraremos cómo sumar filas con celdas en blanco. La función SUMAR.SI.CONJUNTO suma los datos que cumplen ciertos criterios. Podemos utilizar la función SUMAR.SI.CONJUNTO para sumar todas las puntuaciones de los jugadores sin nombre en el siguiente ejemplo.

=SUMAR.SI.CONJUNTO(C3:C8;B3:B8;"")

sumar si esta en blanco ej1

 

Utilizamos las comillas dobles («») para representar una celda en blanco en Excel.

Nuestro ejemplo ignora los jugadores A, B, C y D y suma las puntuaciones de los jugadores desconocidos.

Tratando los Espacios como Celdas en Blanco – Con la Columna Auxiliar

Debe tener cuidado cuando interactúe con celdas en blanco en Excel. Las celdas pueden aparecer en blanco, pero Excel no las tratará como tales. Esto puede ocurrir si la celda contiene espacios, saltos de línea u otros caracteres invisibles. Este es un problema común cuando se importan datos a Excel desde otras fuentes. Si necesitamos tratar las celdas que sólo contienen espacios de la misma manera que si estuvieran en blanco, entonces la fórmula del ejemplo anterior no funcionará.

Observa cómo la fórmula SUMAR.SI.CONJUNTO no considera que la celda B9 de abajo (» «) esté en blanco:

sumar si esta en blanco no espacios

 

Para tratar una celda que sólo contiene espacios como si fuera una celda en blanco, podemos añadir una columna de ayuda con la Función ESPACIOS para eliminar los espacios extra del valor de cada celda:

=ESPACIOS(B3)

Función espacios

 

Aplicamos la Función SUMAR.SI.CONJUNTO a la columna de ayuda, y ahora calcula la suma con precisión.

=SUMAR.SI.CONJUNTO(E3:E9;D3:D9;"")

sumar si esta en blanco o con espacios

 

La columna auxiliar es fácil de crear y fácil de leer, pero es posible que desee tener una sola fórmula para realizar la tarea. Esto se trata en la siguiente sección.

Tratar los espacios como celdas en blanco – sin columna auxiliar

Si una columna auxiliar no es apropiada para sus necesidades, entonces puede utilizar la función SUMAPRODUCTO en combinación con las funciones LARGO y ESPACIOS para sumar las filas en blanco.

=SUMAPRODUCTO(--(LARGO(ESPACIOS(B3:B9))=0);D3:D9)

sumaproducto en blanco o con espacios

 

En este ejemplo, utilizamos la función SUMAPRODUCTO para realizar un complicado cálculo de «suma si». Veamos la fórmula. Esta es nuestra fórmula final:

=SUMAPRODUCTO(--(LARGO(ESPACIOS(B3:B9))=0);D3:D9)

En primer lugar, la función SUMAPRODUCTO enumera el conjunto de valores de los dos rangos de celdas:

=SUMAPRODUCTO(--(LARGO(ESPACIOS({"A";"B";"";"C";"";"XX";""}))=0);{25;10;15;5;8;17;50})

A continuación, la función ESPACIOS elimina los espacios iniciales y finales de los nombres de los jugadores :

=SUMAPRODUCTO(--(LARGO({"A";"B";"";"C";"";"XX";""})=0);{25;10;15;5;8;17;50})

La función LARGO calcula las longitudes de los nombres de los jugadores recortados:

=SUMAPRODUCTO(--({1;1;0;1;0;2;0}=0);{25;10;15;5;8;17;50})

Con la prueba lógica (=0), cualquier nombre de jugador recortado con 0 caracteres se cambia a VERDADERO:

=SUMAPRODUCTO(--({FALSO;FALSO;VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO});{25;10;15;5;8;17;50})

A continuación, los guiones dobles (–) convierten los valores VERDADERO y FALSO en 1s y 0s:

=SUMAPRODUCTO({0;0;1;0;1;0;1};{25;10;15;5;8;17;50})

A continuación, la función SUMAPRODUCTO multiplica cada par de entradas de las matrices para producir una matriz de puntuaciones sólo para los nombres de los jugadores que están en blanco o formados sólo por espacios:

=SUMAPRODUCTO({0; 0; 15; 0; 8; 0; 50)

Finalmente, se suman los números de la matriz:

=73

Puedes encontrar más detalles sobre el uso de sentencias booleanas y del comando «–» en una función SUMAPRODUCTO aquí.

 

Suma si está en blanco en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.

sumar si esta en blanco gsheets

Excel Practice Worksheet

practice excel worksheet

Practice Excel functions and formulas with our 100% free practice worksheets!

  • Automatically Graded Exercises
  • Learn Excel, Inside Excel!

Free Download

Volver a la Lista de Fórmulas de Excel