Sumar Si Por Mes – Excel y Google Sheets

Este tutorial demostrará cómo utilizar la función SUMAR.SI.CONJUNTO para sumar datos correspondientes a meses específicos en Excel y Google Sheets.

 

Sumar Por Mes

En primer lugar, demostraremos cómo sumar los datos correspondientes a las fechas que caen en un mes y año específicos.

Podemos utilizar la función SUMAR.SI.CONJUNTO, junto con las funciones FECHA, AÑO, MES y FIN.MES para sumar el número de ventas dentro de cada mes.

=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;">="&FECHA(AÑO(E3);MES(E3);1);B3:B9;"<="&FIN.MES(E3;0))

 

Para construir la fórmula anterior, empezamos por definir el rango de fechas para cada mes. Utilizamos la función FECHA para definir el primer día del mes (por ejemplo, 5/1/2021). Podemos hacer esto «codificando» la fecha en la fórmula:

">="&FECHA(2021;5;1)

O, mejor aún, podemos flexibilizar el criterio haciendo referencia a una fecha dentro de la celda E3, extrayendo el año y el mes de la fecha (y poniendo el día igual a 1), como se muestra en el ejemplo anterior

">="&FECHA(AÑO(E3);MES(E3);1)

Para definir el último día del mes, podemos utilizar la función FIN.MES:

"<="&EOMONTH(E3,0)

Uniendo todos estos criterios, podemos escribir la siguiente fórmula SUMAR.SI.CONJUNTO

=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;">="&FECHA(AÑO(E3);MES(E3);1);B3:B9;"<="&FIN.MES(E3;0))

Bloqueo de las Referencias de las Celdas

Para que nuestras fórmulas sean más fáciles de leer, hemos mostrado las fórmulas sin referencias de celdas bloqueadas:

=SUMAR.SI.CONJUNTO(C3:C9;B3:B9;">="&FECHA(AÑO(E3);MES(E3);1);B3:B9;"<="&FIN.MES(E3;0))

Pero estas fórmulas no funcionarán correctamente cuando se copien y peguen en otro lugar del archivo. En su lugar, debes utilizar referencias de celdas bloqueadas como esta

=SUMAR.SI.CONJUNTO($C$3:$C$9;$B$3:$B$9;">="&FECHA(AÑO(E3);MES(E3);1);$B$3:$B$9;"<="&FIN.MES(E3;0))

Lea nuestro artículo sobre el bloqueo de referencias de celdas para obtener más información.

Formateo de los Valores del Mes

En este ejemplo, hemos enumerado los meses en la columna E. Estos valores de mes son en realidad fechas formateadas para omitir el día, utilizando un formato numérico personalizado.

El formato de datos personalizado es «mmm aaaa» para mostrar «may 2021».

Suma Por Mes en Varios Años

El ejemplo anterior sumó datos con fechas que cayeron dentro de un mes y año específicos. En cambio, puede sumar datos con fechas que caen dentro de un mes en cualquier año usando la función SUMAPRODUCTO.

=SUMAPRODUCTO(C3:C8;--(MES(B3:B8)=MES(E3)))

En este ejemplo, utilizamos la función SUMAPRODUCTO para realizar complicados cálculos de «sumar si». Veamos la fórmula.

Esta es nuestra fórmula final:

=SUMAPRODUCTO(C3:C8;--(MES(B3:B8)=MES(E3)))

En primer lugar, la función SUMAPRODUCTO enumera el número de ventas para cada fecha de venta y luego compara el mes de cada fecha de venta con el mes especificado, devolviendo VERDADERO si los meses coinciden, o FALSO si no lo hacen:

=SUMAPRODUCTO({30;42;51;28;17;34};--({VERDADERO;FALSO;VERDADERO;FALSO;VERDADERO;FALSO}))

A continuación, los guiones dobles (–) convierten los valores VERDADERO y FALSO en 1s y 0s:

=SUMAPRODUCTO({30;42;51;28;17;34};{1;0;1;0;1;0})

A continuación, la función SUMAPRODUCTO multiplica cada par de entradas de las matrices:

=SUMAPRODUCTO({30;0;51;0;17;0})

Por último, se suman los números de la matriz:

=98

Puedes encontrar más detalles sobre el uso de sentencias booleanas y del comando «–» en una función SUMAPRODUCTO aquí

Suma Por Mes en Google Sheets

Estas fórmulas funcionan exactamente igual en Google Sheets que en Excel.