Somme du Mois jusqu’à une Date ou de l’Année jusqu’à une Date – Excel et Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

David Gagnon

Last updated on février 5, 2023

Download Example Workbook

Télécharger le Classeur Exemple

Ce tutoriel montre comment utiliser la fonction SOMME.SI.ENS pour additionner des données du mois ou de l’année en cours dans Excel et Google Sheets.

somme mois annee jusqua date fonction principale

Somme du Mois en Cours (jusqu’à Aujourd’hui)

La fonction SOMME.SI.ENS additionne les données des lignes qui répondent à certains critères. Sa syntaxe est la suivante :

Cet exemple additionne les tables réservées depuis le début du mois, en utilisant les fonctions : SOMME.SI.ENS, DATE, ANNEE, MOIS et AUJOURDHUI.

=SOMME.SI.ENS(C3:C11;B3:B11;">="&DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1);B3:B11;"<="&AUJOURDHUI())

somme mois annee jusqua date exemple mois courant

Examinons maintenant cette formule.

Fonction AUJOURDHUI

La fonction AUJOURDHUI renvoie la date du jour. La valeur est recalculée à chaque fois que le fichier est consulté.

=AUJOURDHUI()

somme mois annee jusqua date exemple mois courant etape 1

Il s’agit de l’extrémité supérieure de notre plage de dates pour la formule.

Fonction DATE

Calculez ensuite l’extrémité inférieure de la plage de dates : le premier jour du mois en cours. Nous utilisons la fonction DATE avec ANNEE et MOIS pour produire cette valeur de date. Utilisez l’année et le mois de la date du jour et attribuez la valeur 1 au jour.

=DATE(ANNEE(E3);MOIS(E3);1)

somme mois annee jusqua date exemple mois courant etape 2

Fonction SOMME.SI.ENS

Utilisez la fonction SOMME.SI.ENS pour additionner les tables réservées lorsque la date est supérieure ou égale au premier jour du mois et inférieure ou égale au jour actuel.

=SOMME.SI.ENS(C3:C11;B3:B11;">="&F3;B3:B11;"<="&E3)

somme mois annee jusqua date exemple mois courant etape 3

En combinant ces étapes, nous obtenons la formule pour la somme du mois en cours :

=SOMME.SI.ENS(C3:C11;B3:B11;">="&DATE(ANNEE(AUJOURDHUI());MOIS(AUJOURDHUI());1);B3:B11;"<="&AUJOURDHUI())

somme mois annee jusqua date exemple mois courant

Somme de l’Année Courante

La même logique peut être utilisée pour additionner le nombre de tables réservées pour l’année en cours jusqu’à la date d’aujourd’hui en faisant en sorte que la date de début soit le premier jour de l’année. Le mois et le jour sont tous deux définis à 1.

=SOMME.SI.ENS(C3:C11;B3:B11;">="&DATE(ANNEE(AUJOURDHUI());1;1);B3:B11;"<="&AUJOURDHUI())

somme mois annee jusqua date exemple annee courante

Verrouillage des Références de Cellule

Pour faciliter la lecture de nos formules, nous les avons présentées sans les références de cellule verrouillées :

=SOMME.SI.ENS(C3:C11;B3:B11;">="&DATE(ANNEE(AUJOURDHUI());1;1);B3:B11;"<="&AUJOURDHUI())

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier Excel. Au lieu de cela, vous devez utiliser des références de cellules verrouillées comme ceci :

=SOMME.SI.ENS($C$3:$C$11;$B$3:$B$11;">="&DATE(ANNEE(AUJOURDHUI());1;1);$B$3:$B$11;"<="&AUJOURDHUI())

somme mois annee jusqua date exemple annee courante ref verrouillee

Pour en savoir plus, lisez notre article sur le verrouillage des références de cellule.

Somme du Mois ou de l’Année Courante dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel.

somme mois annee jusqua date google sheets