Somme Si en Fonction du Mois – Excel et Google Sheets

Ce tutoriel montre comment utiliser la fonction SOMME.SI.ENS pour additionner des données correspondant à des mois spécifiques dans Excel et Google Sheets.

Somme Si en Fonction du Mois

Tout d’abord, nous allons montrer comment additionner des données correspondant à des dates qui tombent dans un mois et une année spécifiques.

Nous pouvons utiliser la fonction SOMME.SI.ENS, ainsi que les fonctions DATE, ANNEE, MOIS et FIN.MOIS pour additionner le nombre de ventes dans chaque mois.

=SOMME.SI.ENS(C3:C9;B3:B9;">="&DATE(ANNEE(E3);MOIS(E3);1);B3:B9;"<="&FIN.MOIS(E3;0))

Pour construire la formule ci-dessus, nous commençons par définir la plage de dates pour chaque mois. Nous utilisons la fonction DATE pour définir le premier jour du mois (ex. 5/1/2021). Nous pouvons le faire en « codant en dur » la date dans la formule :

">="&DATE(2021;5;1)

Ou, mieux encore, nous pouvons rendre les critères flexibles en faisant référence à une date dans la cellule E3; en extrayant l’année et le mois de la date (et en fixant le jour à 1); comme le montre l’exemple ci-dessus :

">="&DATE(ANNÉE(E3);MOIS(E3);1)

Pour définir le dernier jour du mois, nous pouvons utiliser la fonction FIN.MOIS :

"<="&MOIS(E3;0)

En réunissant tous ces critères, nous pouvons écrire la formule SOMME.SI.ENS suivante :

=SOMME.SI.ENS(C3:C9;B3:B9;">="&DATE(ANNEE(E3);MOIS(E3);1);B3:B9;"<="&FIN.MOIS(E3;0))

Verrouillage des Références de Cellule

Pour faciliter la lecture de nos formules, nous avons représenté les formules sans les références de cellule verrouillées :

=SOMME.SI.ENS(C3:C9;B3:B9;">="&DATE(ANNEE(E3);MOIS(E3);1);B3:B9;"<="&FIN.MOIS(E3;0))

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier. Vous devez plutôt utiliser des références de cellules verrouillées comme ceci :

=SOMME.SI.ENS($C$3:$C$9;$B$3:$B$9;">="&DATE(ANNEE(E3);MOIS(E3);1);$B$3:$B$9;"<="&FIN.MOIS(E3;0))

Lisez notre article sur le verrouillage des références de cellule pour en savoir plus.

Formatage des Valeurs de Mois

Dans cet exemple, nous avons répertorié les mois dans la colonne E. Ces valeurs mensuelles sont en fait des dates formatées pour omettre le jour, à l’aide d’un formatage numérique personnalisé.

Le format de données personnalisé est « mmm yyyy » pour indiquer mai 2021.

Somme en Fonction du Mois sur Plusieurs Années

L’exemple ci-dessus additionnait des données dont les dates étaient comprises dans un mois et une année spécifiques. Au lieu de cela, vous pouvez additionner des données dont les dates sont comprises dans un mois de n’importe quelle année en utilisant la fonction SOMMEPROD.

=SOMMEPROD(C3:C8;--(MOIS(B3:B8)=MOIS(G3)))

Dans cet exemple, nous utilisons la fonction SOMMEPROD pour effectuer des calculs complexes de type « somme si ». Examinons cette formule.

Voici notre formule finale :

=SOMMEPROD(C3:C8;--(MOIS(B3:B8)=MOIS(G3)))

Tout d’abord, la fonction SOMMEPROD répertorie le nombre de ventes pour chaque date de vente, puis compare le mois de chaque date de vente au mois spécifié, en renvoyant VRAI si les mois correspondent, ou FAUX s’ils ne correspondent pas :

=SOMMEPROD({30;42;51;28;17;34};--({VRAI;FAUX;VRAI;FAUX;VRAI;FAUX}))

Ensuite, les doubles tirets (–) convertissent les valeurs VRAI et FAUX en 1 et 0 :

=SOMMEPROD({30;42;51;28;17;34};{1;0;1;0;1;0})

La fonction SOMMEPROD multiplie ensuite chaque paire d’entrées dans les tableaux :

=SOMMEPROD({30;0;51;0;17;0})

Enfin, les nombres du tableau sont additionnés :

=98

Pour plus de détails sur l’utilisation des instructions booléennes et de la commande « — » dans une fonction SOMMEPROD, cliquez ici

Somme Si en Fonction du Mois dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel.