Somme Si Vide – Excel et Google Sheets

Ce tutoriel montre comment utiliser la fonction SOMME.SI.ENS pour additionner les données correspondant à des cellules vides ou vides dans Excel et Google Sheets.

Somme Si Vide

Tout d’abord, nous allons montrer comment additionner des lignes dont les cellules sont vides.

La fonction SOMME.SI.ENS additionne les données qui répondent à certains critères.

Dans l’exemple ci-dessous, nous pouvons utiliser la fonction SOMME.SI.ENS pour additionner tous les pointages des joueurs sans nom.

=SOMME.SI.ENS(C3:C8;B3:B8;"")

Nous utilisons des guillemets doubles («  ») pour représenter une cellule vide dans Excel. Notre exemple ignore les joueurs A, B, C et D et additionne les scores des joueurs inconnus.

Traiter les Espaces Comme des Cellules Vides – Avec une Colonne d’Aide

Vous devez être prudent lorsque vous interagissez avec des cellules vides dans Excel. Les cellules peuvent vous sembler vides, mais Excel ne les traitera pas comme telles. Cela peut se produire si la cellule contient des espaces, des sauts de ligne ou d’autres caractères invisibles. Il s’agit d’un problème courant lors de l’importation de données dans Excel à partir d’autres sources.

Si nous devons traiter les cellules qui ne contiennent que des espaces de la même manière que si elles étaient vides, la formule de l’exemple précédent ne fonctionnera pas. Remarquez que la formule SOMME.SI.ENS ne considère pas la cellule B9 ci-dessous ( » « ) comme étant vide :

Pour traiter une cellule ne contenant que des espaces comme s’il s’agissait d’une cellule vide, nous pouvons ajouter une colonne d’aide avec la fonction SUPPRESPACE pour supprimer les espaces superflus de la valeur de chaque cellule :

=SUPPRESPACE(B3)

Nous appliquons la fonction SOMME.SI.ENS à la colonne auxiliaire, qui calcule maintenant la somme de la façon attendue.

=SOMME.SI.ENS(E3:E9;D3:D9;"")

La colonne d’aide est facile à créer et à lire, mais vous souhaiterez peut-être n’avoir qu’une seule formule pour accomplir la tâche. Cette question est abordée dans la section suivante.

Traiter les Espaces Comme des Cellules Vides – Sans Colonne d’Aide

Si une colonne d’aide ne répond pas à vos besoins, vous pouvez utiliser la fonction SOMMEPROD en combinaison avec les fonctions NBCAR et SUPPRESPACE pour additionner les lignes vides.

=SOMMEPROD(--(NBCAR(SUPPRESPACE(B3:B9))=0);D3:D9)

Dans cet exemple, nous utilisons la fonction SOMMEPROD pour effectuer un calcul complexe de type « Somme.Si.Ens ». Parcourons la formule.

Voici notre formule finale :

=SOMMEPROD(--(NBCAR(SUPPRESPACE(B3:B9))=0);D3:D9)

Tout d’abord, la fonction SOMMEPROD liste le tableau des valeurs des deux plages de cellules :

=SOMMEPROD(--(NBCAR(SUPPRESPACE({"A"; "B"; ""; "C"; ""; "XX"; ""}))=0);{25; 10; 15; 5; 8; 17; 50})

Ensuite, la fonction SUPPRESPACE supprime les espaces de début et de chaque nom de joueur :

=SOMMEPROD(--(NBCAR({"A"; "B"; ""; "C"; ""; "XX"; ""})=0);{25; 10; 15; 5; 8; 17; 50})

La fonction NBCAR calcule la longueur des noms de joueurs coupés :

=SOMMEPROD(--({1; 1; 0; 1; 0; 2; 0}=0);{25; 10; 15; 5; 8; 17; 50})

Avec le test logique (=0), tous les noms de lecteurs rognés comportant 0 caractères sont transformés en valeur VRAI :

=SOMMEPROD(--({FALSE; FALSE; TRUE; FALSE; TRUE; FALSE; TRUE});{25; 10; 15; 5; 8; 17; 50})

Ensuite, les doubles tirets (–) convertissent les valeurs VRAI et FAUX en 1 et 0  respectivement:

=SOMMEPROD({0; 0; 1; 0; 1; 0; 1};{25; 10; 15; 5; 8; 17; 50})

La fonction SOMMEPROD multiplie ensuite chaque paire d’entrées dans les tableaux pour produire un tableau de pointages uniquement pour les noms de joueurs qui sont vides ou composés uniquement d’espaces :

=SOMMEPROD({0; 0; 15; 0; 8; 0; 50})

Enfin, les chiffres du tableau sont additionnés :

=73

Vous trouverez plus de détails sur l’utilisation des instructions booléennes et de la commande « — » dans une fonction SOMMEPROD ici.

Somme Si Vide dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel.