Supprimer des Chiffres d’un Texte dans Excel et Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

David Gagnon

Last updated on février 8, 2023

Download Example Workbook

Télécharger le Classeur Exemple

Ce tutoriel montre comment supprimer des chiffres dans le texte d’une cellule dans Excel et Google Sheets.

supprimer chiffres dans texte fonction principale

Nous aborderons deux formules différentes pour supprimer des chiffres d’un texte dans Excel.

Formule avec la fonction SUBSTITUE

Nous pouvons utiliser une formule basée sur la fonction SUBSTITUE. C’est une formule longue mais c’est l’une des façons les plus simples de supprimer des chiffres d’une chaîne alphanumérique.

Dans cette formule, nous avons imbriqué les fonctions SUBSTITUE 10 fois (une pour chaque nombre : 0,1,…,9), comme ceci :

=SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(
B3;1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;"");0;"")

supprimer chiffre texte fonction substitue imbriquees

Formule Tableau JOINDRE.TEXTE

Pour supprimer des chiffres dans des chaînes alphanumériques, nous pouvons également utiliser une formule de tableau complexe composée des fonctions JOINDRE.TEXTE, STXT, LIGNE et INDIRECT.

{=JOINDRE.TEXTE("";VRAI;SI(ESTERR(STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)+0);STXT(B3;LIGNE(
INDIRECT("1:"&NBCAR(B3)));1);""))}

supprimer chiffres dans texte formule complete joindre texte

Remarque : JOINDRE.TEXTE est une nouvelle fonction Excel disponible dans Excel 2019+ et Office 365.

Cette formule est complexe, nous allons donc la diviser en étapes pour mieux la comprendre.

Étape 1

La fonction STXT est une fonction de texte qui renvoie le texte au milieu d’une cellule. Vous devez indiquer le nombre de caractères à retourner et le caractère de départ.

Pour l’argument du numéro de départ (no_depart) dans la fonction STXT, nous utiliserons la liste du tableau résultant des fonctions LIGNE et INDIRECT.

=LIGNE(INDIRECT("1:"&NBCAR(B3)))

supprimer chiffres dans texte formule joindre texte etape 1

Pour le nombre de caractères (no_cars), utilisez 1. Après avoir entré les arguments dans la fonction STXT, celle-ci renvoie un tableau.

{=STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)}

supprimer chiffres dans texte formule joindre texte etape 1.5

Étape 2

Nous allons ajouter zéro (+ 0) à chaque valeur du tableau résultant (que nous obtenons de la fonction STXT ci-dessus). Dans Excel, si des chiffres sont ajoutés à des caractères non numériques, nous obtenons l’erreur : #VALEUR! Ainsi, après avoir ajouté 0 dans le tableau ci-dessus, nous obtiendrons un tableau de chiffres et des erreurs #VALEUR!

{=STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)+0}

supprimer chiffres dans texte formule joindre texte etape 2

Étape 3

Utilisez ensuite la fonction ESTERR pour renvoyer VRAI pour les erreurs et FAUX pour les valeurs sans erreur, en produisant un tableau de VRAI et FAUX, VRAI pour les caractères non numériques et FAUX pour les nombres.

=ESTERR(STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)+0)

supprimer chiffres dans texte formule joindre texte etape 3

Étape 4

Ajoutez ensuite la fonction SI.

La fonction SI va vérifier le résultat de la fonction ESTERR (étape 3). Si sa valeur est VRAI, elle renverra un tableau de tous les caractères d’une chaîne alphanumérique. Pour cela, nous avons ajouté une autre fonction STXT sans ajouter de zéro à la fin. Si la valeur de la fonction SI est FAUX, elle renverra un blanc (« »).

De cette façon, nous aurons un tableau qui contient uniquement les caractères non numériques de la chaîne.

=SI(ESTERR(STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)+0);STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1);"")

supprimer chiffres dans texte formule joindre texte etape 4

Étape 5

Enfin, le tableau ci-dessus est placé dans la fonction JOINDRE.TEXTE. La fonction JOINDRE.TEXTE va joindre tous les caractères du tableau ci-dessus et ignorer les chaînes vides.

Le délimiteur de cette fonction est défini comme une chaîne vide (« ») et la valeur de l’argument ignorer_vide est défini à VRAI.

Cela nous donnera le résultat souhaité, c’est-à-dire uniquement les caractères non numériques de la chaîne alphanumérique.

{=JOINDRE.TEXTE("";VRAI;SI(ESTERR(STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)+0);
STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1);""))}

supprimer chiffres dans texte formule joindre texte finale

Remarque : il s’agit d’une formule de tableau. Lorsque vous saisissez des formules de tableau dans Excel 2019 ou antérieur, vous devez utiliser CTRL + SHIFT + ENTRÉE pour saisir la formule au lieu de saisir simplement ENTRÉE comme d’habitude.

Vous saurez que vous avez saisi la formule correctement grâce aux accolades qui apparaissent. NE TAPEZ PAS manuellement les accolades, la formule ne fonctionnera pas.

Avec Office 365 (et vraisemblablement les versions d’Excel postérieures à 2019), vous pouvez simplement saisir la formule comme d’habitude.

Fonction SUPPRESPACE

Lorsque les chiffres sont supprimés de la chaîne de caractères, il se peut qu’il reste des espaces supplémentaires. Pour supprimer tous les espaces de queue et de tête, ainsi que les espaces supplémentaires entre les mots, nous pouvons utiliser la fonction SUPPRESPACE avant la formule principale, comme ceci :

=SUPPRESPACE(C3)

supprimer chiffres dans texte formule joindre texte etape 5

Suppression des Nombres dans un Texte dans Google Sheets

La formule permettant de supprimer les chiffres du texte fonctionne exactement de la même manière dans Google Sheets et dans Excel :

supprimer chiffres dans texte formule complete joindre texte google sheets

Notez que certaines fonctions ne sont pas traduite en français dans Google Sheets. Il faut donc utiliser le nom anglais de ces fonctions, comme c’est le cas ici avec la fonction TEXTJOIN (équivalent à JOINDRE.TEXTE).

Il faut également explicitement spécifier que la formule est une formule de tableau à l’aide de la fonction ARRAYFORMULA.