현재까지의 월별 합계 또는 연도별 합계 – Excel 및 Google 스프레드시트

이 튜토리얼에서는 SUMIFS 함수를 사용하여 Excel 및 Google 스프레드시트에서 월별 또는 연도별 데이터의 합계를 계산하는 방법을 보여드립니다.

현재까지의 월별 합계

SUMIFS 함수는 특정 기준을 충족하는 행의 데이터를 합산합니다. 구문은 다음과 같습니다.

이 예에서는 함수를 사용하여 현재까지의 월별 테이블 예약을 합산합니다: SUMIFS, DATE, YEAR, MONTH 및 TODAY

=SUMIFS(C3:C11,B3:B11,">="&DATE(YEAR(TODAY()),MONTH(TODAY()),1),B3:B11,"<="&TODAY())

이제 수식을 단계별로 살펴봅시다.

TODAY 함수

TODAY 함수는 현재 날짜를 반환합니다. 이 값은 파일을 볼 때마다 다시 계산됩니다.

=TODAY()

이 값은 수식 날짜 범위의 상한값이 됩니다.

DATE 함수

그런 다음 날짜 범위의 하한값인 현재 달의 첫날을 계산합니다. 이 날짜 값을 생성하기 위해 DATE 함수를 YEAR및 MONTH함수와 함께 사용합니다. 오늘 날짜의 연도와 월을 사용하고 1일로 설정합니다.

=DATE(YEAR(E3),MONTH(E3),1)

SUMIFS 함수

날짜가 해당 월의 첫날보다 크거나 같고 현재 날짜보다 작을 때의 테이블 예약건을 합산하려면 SUMIFS 함수를 사용합니다.

=SUMIFS(C3:C11,B3:B11,">="&F3,B3:B11,"<="&E3)

이 단계를 결합하면 현재 까지의 월별 합계에 대한 수식이 나옵니다.

=SUMIFS(C3:C11,B3:B11,">="&DATE(YEAR(TODAY()),MONTH(TODAY()),1),B3:B11,"<="&TODAY())

현재까지 연도별 합계

동일한 논리를 사용하여 시작 날짜를 연도의 첫날로 설정하여 현재 연도의 오늘까지의 테이블 예약 수를 합산할 수 있습니다. 월과 일 모두 1로 설정됩니다.

=SUMIFS(C3:C11,B3:B11,">="&DATE(YEAR(TODAY()),1,1),B3:B11,"<="&TODAY())

셀 참조 고정

수식을 더 쉽게 읽을 수 있도록 셀 참조를 고정하지 않고 표시했습니다.

=SUMIFS(C3:C11,B3:B11,">="&DATE(YEAR(TODAY()),1,1),B3:B11,"<="&TODAY())

하지만 이러한 수식은 Excel 파일에서 다른 곳에 복사하여 붙여넣으면 제대로 작동하지 않습니다. 대신 다음과 같이 셀 절대 참조를 사용해야 합니다.

=SUMIFS($C$3:$C$11,$B$3:$B$11,">="&DATE(YEAR(TODAY()),1,1),$B$3:$B$11,"<="&TODAY())

자세한 내용은 셀 참조 고정 문서를 참조하세요.

Google 스프레드시트에서 월별 또는 연도별 합계하기

이 수식은 Google 스프레드시트에서도 Excel에서와 똑같이 작동합니다.