Formatação Condicional com Base no Resultado PROCV – Excel e Google Planilhas
Este tutorial demonstra vários exemplos de como aplicar a formatação condicional com base no resultado de uma função PROCV no Excel e no Google Planilhas. Se a sua versão do Excel for compatível com a função PROCX, recomendamos usar a função PROCX.
Vejamos um exemplo em que queremos aplicar a formatação condicional com base no resultado de uma função PROCV.
Formato com Base na Comparação de PROCV
Primeiro, aplicaremos a formatação condicional à tabela de Nomes e IDs de Estudante (col. E-H) pesquisando as notas de cada aluno (col. B-C) e aplicaremos a cor de preenchimento de célula VERMELHA se as pontuações estiverem abaixo de 72. O resultado é mostrado acima, mas vamos percorrer as etapas abaixo.
=PROCV($F3;$B$3:$C$7;2;FALSO)<72
Vejamos como aplicar a fórmula acima na formatação condicional.
Aplicar a Formatação Condicional
- Destaque o intervalo em que a formatação condicional será aplicada.
- Na faixa de opções, vá para a guia Página inicial > Grupo de estilos > Formatação condicional > Nova regra.
- No menu pop-up, selecione Tipo de regra: Usar uma fórmula para determinar quais células devem ser formatadas.
- Na Barra de Fórmulas, insira nossa fórmula.
- Clique em Formatar e defina suas configurações de formatação. No nosso caso, escolheremos uma cor de preenchimento VERMELHA. Clique em OK.
- Agora clique em OK e a regra de formatação condicional será aplicada.
Agora que sabemos como aplicar a formatação condicional, vamos examinar a fórmula.
Pode ser útil começar inserindo sua(s) fórmula(s) de formatação condicional nas células para testar se elas funcionam como esperado. Faremos isso a seguir.
Função PROCV
Primeiro, executamos o PROCV.
=PROCV($F3;$B$3:$C$7;2;FALSO)
Usamos $s para bloquear as referências de células. Isso é essencial para criar uma fórmula que funcione em todas as linhas.
Comparação Lógica
Em seguida, os resultados são comparados com o critério definido.
=H3<72
A formatação condicional alterará a cor da célula para todas as linhas com VERDADEIRO.
A combinação de todas as fórmulas resulta em nossa fórmula original PROCV:
=PROCV($F3;$B$3:$C$7;2;FALSO)<72Formatar se o PROCV Estiver em Branco
Observe que, no exemplo anterior, um aluno não obteve pontuação. Podemos detectar e destacar essas células adicionando a função ÉCEL.VAZIA:
=ÉCÉL.VAZIA(PROCV($F3;$B$3:$C$7;2;FALSO))
É assim que a fórmula será avaliada:
Formatar se o PROCV Estiver Dentro do Intervalo de Valores
Outro cenário comum com o PROCV é verificar se o valor está dentro de um determinado intervalo de valores.
Para fazer isso, podemos usar a função E junto com a PROCV:
=E(PROCV($F3;$B$3:$C$7;2;FALSO)>=72;PROCV($F3;$B$3:$C$7;2;FALSO)<=74)
Vamos examinar a fórmula:
Limite Inferior
Primeiro, verificamos se o resultado do nosso PROCV é maior ou igual a um determinado limite inferior (por exemplo, 72).
=H3>=72
Limite Superior
Em seguida, verificamos se esse mesmo valor é menor ou igual ao limite superior (por exemplo, 74).
=H3<=74
Função E
Por fim, usamos a função E para verificar se ambas as condições são VERDADEIRAS.
=E(I3;J3)
A combinação das fórmulas acima resulta em nossa fórmula original:
=E(PROCV($F3;$B$3:$C$7;2;FALSO)>=72;PROCV($F3;$B$3:$C$7;2;FALSO)<=74)Formatação Condicional – Várias Condições PROCV
Você pode adicionar facilmente várias regras de formatação condicional:
As regras de formatação condicional são aplicadas em ordem (de cima para baixo). Se a opção Parar se Verdadeiro estiver marcada, se essa condição for atendida, nenhuma outra regra de formatação será testada ou aplicada.
Em nosso exemplo específico, o PROCV em branco (por exemplo, Linha 6) satisfaz duas condições, a vermelha (por exemplo, <72) e a laranja (por exemplo, ÉCEL.VAZIA). Como a regra ÉCEL.VAZIA é aplicada primeiro e Parar se Verdadeiro está marcada verificada, a LINHA 6 é destacada em LARANJA porque a condição ÉCEL.VAZIA é atendida e as regras subsequentes não são testadas.
Formatação Condicional com Base no Resultado da PROCV no Google Planilhas
Todas as fórmulas discutidas acima funcionam da mesma forma no Google Planilhas.
Veja a seguir as etapas para aplicar a formatação condicional para célula em branco no Google Planilhas :
=ÉCÉL.VAZIA(PROCV($F3;$B$3:$C$7;2;FALSO))
- Destaque o intervalo e, em seguida, vá para a guia Formatar > Formatação condicional
- Na barra lateral, vá para “Regras de formatação” e selecione “A fórmula personalizada é”
- Insira nossa fórmula na barra de fórmulas, defina o estilo de formatação e clique em Concluído:
- No caso de a matriz de busca não estar na mesma planilha, no Google Planilhas é necessário utilizar a função INDIRETO para fazer a referência da matriz de busca, e então o resultado será equivalente ao mostrado:
=ÉCÉL.VAZIA(PROCV($F3;INDIRETO("Notas!$B$3:$C$7");2;FALSO))
