PROCX Múltiplos Critérios
Este tutorial vai demonstrar como executar um PROCX com vários critérios no Excel. Se a sua versão do Excel não for compatível com o PROCX, veja como usar o PROCV.
Concatenação de Múltiplos Critérios PROCX
Uma maneira comum de executar um PROCX com vários critérios é concatenar todos os critérios em um valor de pesquisa, e suas colunas de pesquisa correspondentes em uma matriz de pesquisa.
=PROCX(F3&G3;B3:B7&C3:C7;D3:D7)
Vamos examinar a fórmula:
Concatenar as Colunas de Pesquisa
Primeiro, concatenamos as colunas de pesquisa para criar uma matriz de IDs exclusivos, o que nos permite pesquisar todos os critérios simultaneamente.
=B3&C3
Concatenar os Critérios
Em seguida, também fazemos o mesmo com os critérios para criar um novo valor de pesquisa.
=F3&G3
Função PROCX
Por fim, fornecemos o novo valor de pesquisa e a matriz de pesquisa à função PROCX.
=PROCX(K3;I3:I7;D3:D7)
Juntando tudo isso, obtém-se a fórmula original:
=PROCX(F3&G3;B3:B7&C3:C7;D3:D7)Expressões Booleanas de Múltiplos Critérios PROCX
Outra opção é criar expressões booleanas em que os critérios são verificados em relação às colunas de pesquisa correspondentes.
=PROCX(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
Vamos examinar essa fórmula:
Expressões Booleanas
Primeiro vamos aplicar os critérios apropriados às colunas correspondentes usando os operadores lógicos (por exemplo =, <, >).
Vamos começar com o primeiro critério (por exemplo, ID do estudante).
=B3=$F$3
Repita a etapa para os outros critérios (por exemplo, Matéria).
=C3=$G$3
Matriz E
Em seguida, executamos o equivalente em matriz da função E multiplicando as matrizes booleanas em que VERDADEIRO é 1 e FALSO é 0.
=I3*J3
Observação: a função E é uma função agregada (muitas entradas para uma saída). Portanto, não podemos usá-la em cálculos de matriz.
Função PROCX
Em seguida, procuramos 1 no resultado da matriz E.
=PROCX(1;K3:K7;D3:D7)
A combinação de todas as fórmulas resulta em nossa fórmula original:
=PROCX(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
