Somar Condicional (SOMASES) com PROCV – Excel e Google Planilhas

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Luciano Farina

Last updated on July 3, 2023

Este tutorial vai demonstrar como usar a função PROCV aninhada na função SOMASES para somar as linhas de dados que correspondem a um valor decodificado no Excel e no Google Planilhas.

mf somases procv

PROCV com SOMASES

Este exemplo somará o total de vendas de todos os códigos de produto que correspondem a um determinado nome de produto, definido em uma tabela de referência.

=SOMASES(F3:F9;E3:E9;PROCV(H3;B3:C9;2;FALSO))

somases procv

Neste exemplo não é possível usar o nome do produto diretamente na função SOMASES, pois a tabela de vendas contém apenas códigos de produtos. Precisamos converter o nome em um código para calcular corretamente o total de vendas .

Vamos dividir a fórmula em etapas.

Função SOMASES

Se soubermos o código do produto (“T1”), podemos simplesmente usar a função SOMASES:

=SOMASES(F3:F9;E3:E9;"T1")

somases

Essa fórmula soma todas as vendas correspondentes ao código “T1”.

Função PROCV

No entanto, se o código do produto não fornecer informações suficientes, precisaremos permitir que um nome de produto seja usado em seu lugar. Podemos usar a função PROCV para transformar o nome (“Mesa”) em seu código:

=PROCV("Mesa";B3:C9;2;FALSO)

procv

Essa fórmula encontra “Mesa” no intervalo de dados Pesquisa de código do produto e faz a correspondência com o valor na segunda coluna desse intervalo (“T1”). Usamos o parâmetro FALSO na função PROCV para indicar que estamos procurando uma correspondência exata.

Uso de PROCV com SOMASES – Referências de células

Agora que mostramos como somar Vendas por Código e como procurar Código por Nome, combinamos essas etapas em uma única fórmula.

Primeiro, substitua “Mesa” na função PROCV por sua referência de célula (H3).

PROCV(H3;B3:C9;2;FALSO)

A entrada do PROCV é “Mesa” e a saída é “T1”, portanto, podemos substituir “T1” na função SOMASES pela função PROCV para obter nossa fórmula final:

=SOMASES(F3:F9;E3:E9;PROCV(H3;B3:C9;2;FALSO))

Bloqueio de referências de células

Para facilitar a leitura, mostramos nossas fórmulas sem referências de células bloqueadas até aqui:

=SOMASES(F3:F9;E3:E9;PROCV(H3;B3:C9;2;FALSO))

Desta forma, porém, essas fórmulas não funcionarão corretamente quando forem copiadas e coladas em outro local do arquivo. De uma forma melhor você deve usar referências de células bloqueadas, como esta:

=SOMASES($F$3:$F$9;$E$3:$E$9;PROCV(H3;$B$3:$C$9;2;FALSO))

Leia nosso artigo sobre Bloqueio de referências de células para saber mais.

Soma condicional com PROCV no Google Planilhas

Essas fórmulas funcionam exatamente da mesma forma no Google Planilhas e no Excel.

somases procv google