Texto Reverso no Excel e no Google Planilhas

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Luciano Farina

Last updated on July 27, 2023

Este tutorial vai demonstrar como reverter o texto em uma célula no Excel e no Google Planilhas.

mf texto reverso

Inverter Texto – Fórmula Simples

A maneira mais simples de inverter uma cadeia de texto no Excel é com as funções UNIRTEXTO e EXT.TEXTO.

=UNIRTEXTO("";1;EXT.TEXTO(B6;{15\14\13\12\11\10\9\8\7\6\5\4\3\2\1};1))

texto reverso 1

Observação: Essa fórmula só funcionará para texto com 15 caracteres ou menos. Para trabalhar com cadeias de texto mais longas, você deve adicionar uma matriz de constantes maior ou usar a fórmula de Matriz Dinâmica abaixo.

Como essa Fórmula Funciona?

A função EXT.TEXTO extrai caractere(s) de uma cadeia de texto. Em nosso exemplo, dissemos à função EXT.TEXTO para extrair apenas um caractere. Em seguida, ao definir a matriz de constantes {15,14,13,12,11,10,9,8,7,6,5,4,3,2,1} como a posição inicial, a função EXT.TEXTO produzirá o texto na ordem inversa.

A função UNIRTEXTO junta o resultado da matriz de constantes, produzindo o texto em ordem inversa.

Texto Invertido – Matriz Dinâmica

A fórmula simples apresentada acima inverterá apenas os primeiros quinze caracteres de um texto. Para inverter mais caracteres, você precisaria adicionar à matriz mais elementos em contagem regressiva, ou pode usar a fórmula dinâmica mostrada abaixo.

A fórmula dinâmica consiste nas funções UNIRTEXTO, EXT.TEXTO, LIN, INDIRETO e NÚM.CARACT.

Etapa 1

A primeira etapa é calcular o número total de caracteres na cadeia de texto e gerar uma matriz de números correspondentes ao número de caracteres:

=LIN(INDIRETO("1:"&NÚM.CARACT(B3)))

texto reverso 6

A fórmula acima é uma fórmula de matriz e você também pode converter a fórmula em fórmula de matriz pressionando Ctrl Shift Enter. Isso adicionará colchetes {} ao redor da fórmula(observação: isso não é necessário nas versões do Excel posteriores ao Excel 2019).

Observação: Quando essas fórmulas forem inseridas na célula, o Excel exibirá apenas o primeiro item da matriz. Para ver o resultado real da fórmula de matriz, você precisa selecionar a célula da fórmula de matriz e pressionar F9 na barra de fórmulas.

Etapa 2

Em seguida, inverta a matriz de números que foi gerada na etapa anterior:

=NÚM.CARACT(B3)-LIN(INDIRETO("1:"&NÚM.CARACT(B3)))+1

texto reverso 5

Etapa 3

Agora, use a função EXT.TEXTO para extrair o texto.

Essa fórmula inverterá a ordem da matriz durante a extração, pegando os caracteres da direita para a esquerda.

=EXT.TEXTO(B3;NÚM.CARACT(B3)-LIN(INDIRETO("1:"&NÚM.CARACT(B3)))+1;1)

texto reverso 7

Etapa Final

Por último, use a função TEXTJOIN para juntar os caracteres individuais.

=UNIRTEXTO("";VERDADEIRO;EXT.TEXTO(B3;NÚM.CARACT(B3)-LIN(INDIRETO("1:"&NÚM.CARACT(B3)))+1;1))

texto reverso 8

Inverter texto no Google Planilhas

A fórmula para inverter o texto funciona exatamente da mesma forma no Google Planilhas e no Excel. Exceto pelo fato de que, quando você fecha a fórmula com CTRL SHIFT ENTER, o Planilhas Google adiciona a função ARRAYFORMULA ao redor da fórmula.

texto reverso google