Doppelter (verschachtelter) XVERWEIS – Dynamische Spalten – Excel
Die Beispielarbeitsmappe herunterladen
In diesem Tutorial zeigen wir Ihnen, wie Sie einen doppelten (verschachtelten) XVERWEIS in Excel durchführen können. Wenn Sie keinen Zugriff auf XVERWEIS haben, können Sie stattdessen auch einen verschachtelten SVERWEIS durchführen.
In Szenarien, in denen ein Kriterium einer Suchaufgabe von einer anderen Suche abhängt, können wir den doppelten (verschachtelten) XVERWEIS verwenden, um verschachtelte Suchen durchzuführen.
Es gibt mindestens drei Argumente in XVERWEIS, in die ein anderer XVERWEIS eingegeben werden kann: der Suchwert (1. Argument), das Nachschlage-Array (2. Argument) und das Rückgabe-Array (3. Argument).
Lassen Sie uns jeden dieser Fälle untersuchen.
XVERWEIS im Suchwert
Wir können einen XVERWEIS ins Suchkriterium von einem anderen XVERWEIS verschachteln.
=XVERWEIS(XVERWEIS(E3;C3:C5;B3:B5);B8:B10;C8:C10)
Sie würden dies tun, wenn das Suchkriterium (z.B. Produkt-ID) von einem anderen Wert abhängig ist (z.B. Produktname).
Schauen wir uns die Formel an:
Zunächst müssen wir den erforderlichen Suchwert für den Haupt-XVERWEIS extrahieren:
=XVERWEIS(E3;C3:C5;B3:B5)
Das Ergebnis aus dem ersten XVERWEIS wird dann in den Haupt-XVERWEIS eingegeben, um eine Suche in der zweiten Tabelle durchzuführen:
=XVERWEIS(F3;B8:B10;C8:C10)
Die Kombination dieser beiden Suchvorgänge führt zu unserer ursprünglichen Formel:
=XVERWEIS(XVERWEIS(E3;C3:C5;B3:B5);B8:B10;C8:C10)XVERWEIS im Nachschlage-Array
Alternativ können wir auch einen verschachtelten XVERWEIS verwenden, um die Suchmatrix (Nachschlage-Array) zurückzugeben.
=XVERWEIS(G3;XVERWEIS(F3;B2:C2;B3:C5);D3:D5)
Eine wichtige Eigenschaft der Funktion XVERWEIS besteht darin, dass sie ein 1D-Array (vertikal oder horizontal) zurückgeben kann, wenn das angegebene Rückgabe-Array in 2D (d.h. als Tabelle) vorliegt. Wenn das Nachschlage-Array eine vertikale Liste ist, gibt die XVERWEIS-Funktion eine Zeile zurück, und wenn das Nachschlage-Array eine horizontale Liste ist, gibt sie eine Spalte zurück.
Lassen Sie uns die Formel aufschlüsseln und veranschaulichen:
Zunächst müssen wir eine Suche in den Überschriften (z. B. in den Spalten- oder Zeilenüberschriften) durchführen und die entsprechende Spalte (oder Zeile) zurückgeben:
=XVERWEIS(F3;B2:C2;B3:C5)
Da das Rückgabe-Array 2D ist (z.B. B3:C5) und das Nachschlage-Array eine horizontale Liste ist (z.B. B2:C2), wird XVERWEIS eine Zeile zurückgeben (z.B. C3:C5).
Das Ausgabe-Array von diesem XVERWEIS wird dann in das Nachschlage-Array von unserem Haupt-XVERWEIS eingespeist:
Wenn wir alle diese Elemente zusammenfügen, ergibt sich unsere ursprüngliche Formel:
=XVERWEIS(G3;XVERWEIS(F3;B2:C2;B3:C5);D3:D5)XVERWEIS im Rückgabe-Array
Auf ähnliche Weise können wir einen verschachtelten XVERWEIS verwenden, um ein dynamisches Rückgabe_Array zurückzugeben.
=XVERWEIS(G3;B3:B5;XVERWEIS(H3;C2:E2;C3:E5))
Lassen Sie uns die Formel aufschlüsseln und veranschaulichen:
Wir verwenden die Spaltenüberschriften als Nachschlage-Array für den ersten XVERWEIS:
=XVERWEIS(G3;C2:E2;C3:E5)
Genau wie im vorherigen Abschnitt gibt der XVERWEIS eine Zeile zurück, sobald es eine Übereinstimmung in den Spaltenüberschriften findet.
Das resultierende Ausgabe-Array wird als Rückgabe-Array von unserem Haupt-XVERWEIS verwendet:
=XVERWEIS(I3;B3:B5;H3:H5)
Kombiniert man diese beiden Ergebnisse mit unserer ursprünglichen Formel:
=XVERWEIS(G3;B3:B5;XVERWEIS(H3;C2:E2;C3:E5))
