SUMME-WENN nach Monat oder Jahr bis Datum – Excel & G-Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie die Funktion SUMMEWENNS in Excel und Google Sheets verwenden können, um Daten aus Zeitspannen von Monat bis Datum oder Jahr bis Datum zu summieren.

SUMME – Monat bis Datum

Die Funktion SUMMEWENNS summiert Daten von Zeilen, die bestimmte Kriterien erfüllen. Ihre Syntax lautet:

In diesem Beispiel werden die Tischreservierungen vom Monat bis zum heutigen Datum unter Verwendung der Funktionen: SUMMEWENNS, DATUM, JAHR, MONAT, und HEUTE summiert.

=SUMMEWENNS(C3:C11;B3:B11;">="&DATUM(JAHR(HEUTE());MONAT(HEUTE());1);B3:B11;"<="&HEUTE())

Gehen wir nun die Formel Schritt für Schritt durch.

Die HEUTE-Funktion

Die HEUTE-Funktion gibt das aktuelle Datum zurück. Der Wert wird jedes Mal neu berechnet, wenn die Datei angezeigt wird.

=HEUTE()

Dies ist die Obergrenze unseres Datumsbereichs für die Formel.

Die DATUM-Funktion

Berechnen Sie dann die Untergrenze des Datumsbereichs (den ersten Tag des aktuellen Monats). Wir verwenden die DATUM-Funktion mit JAHR und MONAT, um diesen Datumswert zu erzeugen. Verwenden Sie das Jahr und den Monat des heutigen Datums und setzen Sie den Tag auf 1.

=DATUM(JAHR(E3);MONAT(E3);1)

Die SUMMEWENNS-Funktion

Verwenden Sie die Funktion SUMMEWENNS, um die Tischreservierungen zu summieren, wenn das Datum größer oder gleich dem ersten Tag des Monats und kleiner oder gleich dem aktuellen Tag ist.

=SUMMEWENNS(C3:C11;B3:B11;">="&F3;B3:B11;"<="&E3)

Kombinieren wir diese Schritte, erhalten wir die Formel für die Monatssumme bis zum heutigen Datum:

=SUMMEWENNS(C3:C11;B3:B11;">="&DATUM(JAHR(HEUTE());MONAT(HEUTE());1);B3:B11;"<="&HEUTE())

SUMME – Jahr bis Datum

Die gleiche Logik kann verwendet werden, um die Anzahl der Tischreservierungen für das aktuelle Jahr bis heute zu summieren, indem das Startdatum auf den ersten Tag des Jahres gesetzt wird. Es werden Sowohl der Monat als auch der Tag auf 1 gesetzt.

=SUMMEWENNS(C3:C11;B3:B11;">="&DATUM(JAHR(HEUTE());1;1);B3:B11;"<="&HEUTE())

Zellenbezüge sperren

Um unsere Formeln besser lesbar zu machen, haben wir sie ohne gesperrte Zellbezüge dargestellt:

=SUMMEWENNS(C3:C11;B3:B11;">="&DATUM(JAHR(HEUTE());1;1);B3:B11;"<="&HEUTE())

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihre Excel-Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenbezüge wie diese verwenden:

=SUMMEWENNS($C$3:$C$11;$B$3:$B$11;">="&DATUM(JAHR(HEUTE());1;1);$B$3:$B$11;"<="&HEUTE())

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

SUMME – Monat oder Jahr bis Datum in Google Sheets

Die o. g. Formeln funktionieren in Google Sheets genau so wie in Excel.