Summe wenn nicht leer – Excel und Google Sheets

In diesem Tutorial zeigen wir Ihnen, wie Sie die Funktion SUMMEWENNS in Excel und Google Sheets verwenden können, um Daten, die sich auf nicht leere Zellen  beziehen, zu summieren.

Summe wenn nicht leer

Zunächst zeigen wir, wie Daten, die sich auf nicht leere Zellen beziehen, summiert werden können.

Wir können die Funktion SUMMEWENNS verwenden, um alle Punktzahlen für Spieler mit nicht leeren Namen unter Verwendung vom Kriterium („<>“) zu summieren.

=SUMMEWENNS(C3:C8;B3:B8;"<>")

Behandlung von Leerzeichen als leere Zellen (mit Hilfsspalte)

Bei der Interaktion mit leeren Zellen in Excel müssen Sie vorsichtig sein. Zellen können für Sie leer erscheinen, aber Excel behandelt sie nicht als leer. Dies kann der Fall sein, wenn die Zelle Leerzeichen, Zeilenumbrüche oder andere unsichtbare Zeichen enthält. Dies ist ein häufiges Problem beim Importieren von Daten aus anderen Quellen in Excel.

Wenn wir Zellen, die nur Leerzeichen enthalten, so behandeln müssen, als wären sie leer, dann funktioniert die Formel im vorherigen Beispiel nicht. Beachten Sie, dass die SUMMEWENNS-Formel die Zelle B9 unten (“ „) nicht als leeres Feld betrachtet:

=SUMMEWENNS(D3:D9;B3:B9;"<>")

Um eine Zelle, die nur Leerzeichen enthält, wie eine leere Zelle zu behandeln, können wir eine Hilfsspalte mit den Funktionen LÄNGE und GLÄTTEN hinzufügen.

Mit der GLÄTTEN-Funktion werden die zusätzlichen Leerzeichen aus der Zelle entfernt.

Die LÄNGE-Funktion zählt die Anzahl der verbleibenden Zeichen. Ist die Anzahl 0, dann ist die „geglättete“ Zelle leer.

=LÄNGE(GLÄTTEN(B3))

Verwenden Sie nun die Funktion SUMMEWENNS, um die Summe zu bilden, wenn die Länge des gekürzten Spielernamens > 0 ist.

=SUMMEWENNS(E3:E9;D3:D9;">0")

Die Hilfsspalte ist einfach zu erstellen und leicht zu lesen, aber vielleicht möchten Sie eine einzige Formel haben, um die Aufgabe zu erfüllen. Dies wird im nächsten Abschnitt behandelt.

Behandlung von Leerzeichen als leere Zellen (ohne Hilfsspalte)

Um all dies mit einer einzigen Formel zu erreichen, können wir die Funktion SUMMENPRODUKT in Kombination mit den Funktionen LÄNGE und GLÄTTEN verwenden.

=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN(B3:B9))>0);D3:D9)

Gehen wir die Formel durch.

Zunächst liest die SUMMENPRODUKT-Funktion die Zellenwerte:

=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN({"A"; "B"; ""; "C"; ""; "XX"; ""}))>0);{25; 10; 15; 5; 8; 17; 50})

Anschließend werden führende und nachfolgende Leerzeichen mit der GLÄTTEN-Funktion aus den Spielernamen entfernt:

=SUMMENPRODUKT(--(LÄNGE({"A"; "B"; ""; "C"; ""; "XX"; ""})>0);{25; 10; 15; 5; 8; 17; 50})

Die Funktion LÄNGE berechnet die Längen der „geglätteten“ Spielernamen:

=SUMMENPRODUKT(--({1; 1; 0; 1; 0; 2; 0}>0);{25; 10; 15; 5; 8; 17; 50})

Mit dem logischen Test (>0) werden alle geglätteten Spielernamen mit mehr als 0 Zeichen in WAHR geändert:

=SUMMENPRODUKT(--({WAHR; WAHR; FALSCH; WAHR; FALSCH; WAHR; FALSCH});{25; 10; 15; 5; 8; 17; 50})

Anschließend wandeln die Doppelstriche (–) die Werte WAHR und FALSCH in Einsen und Nullen um:

=SUMMENPRODUKT({1; 1; 0; 1; 0; 1; 0};{25; 10; 15; 5; 8; 17; 50})

Die Funktion SUMMENPRODUKT multipliziert dann jedes Paar von Einträgen in den Arrays, um ein Array von Punktzahlen nur für Spielernamen, die nicht leer sind oder nicht nur aus Leerzeichen bestehen, zu erzeugen:

=SUMMENPRODUKT({25; 10; 0; 5; 0; 17; 0})

Schließlich werden die Zahlen im Array summiert:

=57

Weitere Details zur Verwendung von booleschen Anweisungen und dem Befehl „–“ in einer SUMMENPRODUKT-Funktion finden Sie hier

Summe wenn nicht leer in Google Sheets

Diese Formeln funktionieren in Google Sheets genau so wie in Excel.