Summe & Summe-Wenn mit SVERWEIS – Excel & Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

Zakarya El Oirzadi

Last updated on Februar 9, 2023

Beispielarbeitsmappe herunterladen

Die Beispielarbeitsmappe herunterladen

In diesem Tutorial zeigen wir Ihnen, wie die SVERWEIS-Funktion in der SUMMEWENNS-Funktion in Excel und Google Sheets verschachtelt wird, um Datenzeilen, die einem entzifferten Wert entsprechen, zu summieren. summe wenn mit sverweis hauptfunktion

SVERWEIS innerhalb von SUMMEWENN

In diesem Beispiel summieren wir den Gesamtumsatz für alle Produktcodes, die mit einem bestimmten Produktnamen, der in einer separaten Referenztabelle definiert ist, übereinstimmen.

=SUMMEWENNS(F3:F9;E3:E9;SVERWEIS(H3;B3:C9;2;FALSCH))

sverweis in summewenns funktion

In diesem Beispiel ist es nicht möglich, den Produktnamen direkt in der SUMMEWENNS-Funktion zu verwenden, da die Umsatztabelle nur Produktcodes enthält . Wir müssen den Namen in einen Code umwandeln, um den Gesamtumsatz korrekt zu berechnen. Schauen wir uns die Formel in einzelnen Schritten an:

Die SUMMEWENNS-Funktion

Wenn wir den Produktcode („T1“) kennen, können wir einfach die SUMMEWENNS-Funktion verwenden:

=SUMMEWENNS(F3:F9;E3:E9;"T1")

sverweis in summewenns funktion schritt1 Diese Formel summiert alle Umsätze, die dem Code „T1“ entsprechen.

Die SVERWEIS-Funktion

Wenn der Produktcode jedoch nicht genügend Informationen liefert, um die Zusammenfassung sinnvoll zu gestalten, müssen wir stattdessen einen Produktnamen verwenden. Wir können die SVERWEIS-Funktion verwenden, um den Namen („Tisch“) in seinen Code umzuwandeln:

=SVERWEIS("Tisch";B3:C9;2;FALSCH)

sverweis in summewenns funktion schritt2

Diese Formel findet „Tisch“ im Datenbereich der Produktcodesuche und gleicht ihn mit dem Wert in der zweiten Spalte dieses Bereichs („T1“) ab. Wir verwenden FALSCH in der SVERWEIS-Funktion, um anzuzeigen, dass wir nach einer genauen Übereinstimmung suchen.

SVERWEIS innerhalb von SUMMEWENNS verwenden – Zellenbezüge

Nachdem wir nun gezeigt haben, wie man die Umsätze nach Code summiert und wie man den Code nach Namen sucht, kombinieren wir diese Schritte in einer einzigen Formel. Ersetzen Sie zunächst den Suchbegriff „Tisch“ in der SVERWEIS-Funktion durch seinen Zellenbezug (H3).

SVERWEIS(H3;B3:C9;2;FALSCH)

Die Eingabe der SVERWEIS-Funktion ist „Tisch“ und die Ausgabe ist „T1“. Wir können also „T1“ in der SUMMEWENNS-Funktion durch die SVERWEIS-Funktion ersetzen, um unsere endgültige Formel zu erhalten:

=SUMMEWENNS(F3:F9;E3:E9;SVERWEIS(H3;B3:C9;2;FALSCH))

sverweis in summewenns funktion

Zellenbezüge sperren

Um unsere Formeln besser lesbar zu machen, haben wir die Formeln ohne gesperrten Zellenbezüge dargestellt:

=SUMMEWENNS(F3:F9;E3:E9;SVERWEIS(H3;B3:C9;2;FALSCH))

Diese Formeln funktionieren jedoch nicht richtig, wenn sie kopiert und an anderer Stelle in Ihrer Datei eingefügt werden. Stattdessen sollten Sie gesperrte Zellenbezüge wie den folgenden verwenden:

=SUMMEWENNS($F$3:$F$9;$E$3:$E$9;SVERWEIS(H3;$B$3:$C$9;2;FALSCH))

Lesen Sie unseren Artikel über das Sperren von Zellenbezügen, um mehr zu erfahren.

Summe-Wenn mit SVERWEIS in Google Sheets

Diese Formeln funktionieren in Google Sheets genau so wie in Excel.

summe wenn mit sverweis google sheets