XVERWEIS – Mehrere Kriterien
Die Beispielarbeitsmappe herunterladen
In diesem Tutorial zeigen wir Ihnen, wie Sie einen XVERWEIS mit mehreren Kriterien in Excel durchführen können. Wenn Ihre Excel-Version XVERWEIS nicht unterstützt, lesen Sie, wie Sie stattdessen SVERWEIS verwenden können.
XVERWEIS – Verkettung mehrerer Kriterien
Eine gängige Methode zur Durchführung von einem XVERWEIS mit mehreren Kriterien ist die Verkettung aller einzelnen Kriterien zu einem Suchwert und der entsprechenden Suchspalten zu einem Suchfeld.
=XVERWEIS(F3&G3;B3:B7&C3:C7;D3:D7)
Lassen Sie uns die Formel durchgehen:
Verkettung der Suchspalten
Zunächst verketten wir die Suchspalten, um ein Array eindeutiger IDs zu erstellen, das es uns ermöglicht, alle Kriterien gleichzeitig zu suchen.
=B3&C3
Verkettung der Kriterien
Als Nächstes machen wir dasselbe für die Kriterien, um einen neuen Suchwert zu erstellen.
=F3&G3
Die XVERWEIS-Funktion
Schließlich übergeben wir den neuen Suchwert und das Suchfeld an die XVERWEIS-Funktion.
=XVERWEIS(K3;I3:I7;D3:D7)
Wenn man alles zusammenfügt, erhält man die ursprüngliche Formel:
=XVERWEIS(F3&G3;B3:B7&C3:C7;D3:D7)XVERWEIS – Mehrere Kriterien – Boolesche Ausdrücke
Eine andere Möglichkeit besteht darin, boolesche Ausdrücke zu erstellen, bei denen die Kriterien mit den entsprechenden Suchspalten abgeglichen werden.
=XVERWEIS(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
Gehen wir diese Formel einmal durch:
Boolesche Ausdrücke
Zunächst wenden wir die entsprechenden Kriterien auf die entsprechenden Spalten an, indem wir die logischen Operatoren (z. B. =, <, >) verwenden.
Beginnen wir mit dem ersten Kriterium (z. B. Studenten-ID).
=B3=$F$3
Wiederholen Sie den Schritt für die anderen Kriterien (z. B. Fach).
=C3=$G$3
Das Array-UND
Als Nächstes führen wir das Array-Äquivalent der UND-Funktion aus, indem wir die booleschen Arrays multiplizieren, wobei WAHR gleich 1 und FALSCH gleich 0 ist.
=I3*J3
Hinweis: Die UND-Funktion ist eine Aggregatfunktion (viele Eingänge für einen Ausgang). Daher können wir sie nicht in Array-Berechnungen verwenden.
Die XVERWEIS-Funktion
Als nächstes suchen wir 1 aus dem Ergebnis vom Array-UND.
=XVERWEIS(1;K3:K7;D3:D7)
Die Kombination aller Formeln ergibt unsere ursprüngliche Formel:
=XVERWEIS(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
