XVERWEIS – Mehrere Tabellenblätter auf einmal – Excel & G-Sheets

Dieses Tutorial zeigt Ihnen, wie Sie einen XVERWEIS auf mehrere Blätter in Excel anwenden können. Wenn Ihre Excel-Version XVERWEIS nicht unterstützt oder Sie Google Sheets verwenden, lesen Sie, wie Sie stattdessen SVERWEIS verwenden können.

Die XVERWEIS-Funktion kann nur eine Suche pro Datensatz durchführen. Wenn Sie eine Suche in mehreren Datensätzen durchführen möchten, die in verschiedenen Tabellenblättern gespeichert sind, können Sie einen weiteren XVERWEIS im vierten Argument (d. h. wenn_nicht_gefunden) der XVERWEIS-Funktion einfügen.

Verschachtelter XVERWEIS (wenn nicht gefunden)

Die XVERWEIS-Funktion oder andere Suchformeln geben den Fehler #NV zurück, wenn sie keine Übereinstimmung finden können und wir können ihr viertes Argument verwenden, um den Fehler durch einen benutzerdefinierten Wert zu ersetzen.

Anstelle eines benutzerdefinierten Wertes werden wir einen weiteren XVERWEIS verschachteln, um eine weitere Suche in einem anderen Blatt durchzuführen, wenn die erste Suche keine Übereinstimmung im ersten Blatt finden kann.

XVERWEIS – 2 Tabellenblätter auf einmal

=XVERWEIS(B3;'Abt. A'!$B$3:$B$7;'Abt. A'!$C$3:$C$7;XVERWEIS(B3;'Abt. B'!$B$3:$B$7;'Abt. B'!$C$3:$C$7))

Lassen Sie uns die Formel aufschlüsseln und veranschaulichen:

XVERWEIS-Funktion

Hier ist der XVERWEIS für das erste Blatt, wenn das vierte Argument leer gelassen wird:

=XVERWEIS(B3;'Abt. A'!$B$3:$B$7;'Abt. A'!$C$3:$C$7)

Hinweis: Die XVERWEIS-Funktion benötigt mindestens drei Argumente: Suchwert, Sucharray und Rückgabearray. Standardmäßig findet die XVERWEIS-Funktion eine exakte Übereinstimmung von oben nach unten im sucharray. Sobald sie eine Übereinstimmung findet, gibt sie den entsprechenden Wert aus dem Rückgabe-Array zurück. Andernfalls gibt sie einen Fehler zurück.

Hier ist der XVERWEIS für das zweite Blatt:

=XVERWEIS(B3;'Abt. B'!$B$3:$B$7;'Abt. B'!$C$3:$C$7)

Das Argument „wenn nicht gefunden“

Das 4. Argument von XVERWEIS und die WENNNV-Funktion funktionieren auf die gleiche Weise. Sie prüfen, ob ein Wert dem #NV-Fehler entspricht, und wenn dies der Fall ist, geben sie den eingestellten Wert zurück.

Die Ergebnisse von XVERWEIS für das zweite Blatt (z. B. Abt. B) werden als Ersatzwerte für die #NV-Fehler aus dem XVERWEIS für das erste Blatt (z. B. Abt. A) verwendet.

=XVERWEIS(B3;'Abt. A'!$B$3:$B$7;'Abt. A'!$C$3:$C$7;F3)

Die Kombination all dieser Konzepte führt zu unserer ursprünglichen Formel:

=XVERWEIS(B3;'Abt. A'!$B$3:$B$7;'Abt. A'!$C$3:$C$7;XVERWEIS(B3;'Abt. B'!$B$3:$B$7;'Abt. B'!$C$3:$C$7))

XVERWEIS – Mehr als 2 Blätter auf einmal

Um weitere Blätter hinzuzufügen, müssen wir lediglich einen weiteren XVERWEIS an den letzten XVERWEIS in der Formel anhängen. Hier ist die Formel für 3 Blätter:

=XVERWEIS(B3;'Abt. A'!$B$3:$B$7;'Abt. A'!$C$3:$C$7;XVERWEIS(B3;'Abt. B'!$B$3:$B$7;'Abt. B'!$C$3:$C$7;XVERWEIS(B3;'Abt. C'!$B$3:$B$7;'Abt. C'!$C$3:$C$7)))