E-Mail aus Excel mit einer Formel senden (keine Makros!)

In diesem Tutorial zeigen wir Ihnen, wie Sie eine E-Mail von Excel aus mit einer Formel versenden können (keine Makros erforderlich).

In Excel können Sie eine E-Mail senden, indem Sie ein Makro ausführen. Wenn Sie jedoch kein VBA verwenden möchten, lesen Sie weiter.

Hyperlink-Formel erstellen

In Excel ist es möglich, auf eine Zelle zu klicken und automatisch eine E-Mail zu versenden. Dies kann mit einer Formel unter Verwendung der Funktion HYPERLINK geschehen. Sie können eine Hyperlink-Formel erstellen, die den Befehl mailto verwendet und Felder wie An, Betreff, CC und den Rumpf einer E-Mail automatisch ausfüllt.

=HYPERLINK("mailto:" & C3 & "?subject="&WENN(D3=1;$I$3;WENN(D3=2;$I$4;$I$5)) &"&cc=abclimited@abc.com"&"&body="&WENN(D3=1;$J$3;WENN(D3=2;$J$4;$J$5&E3)) & " " &$J$7; "E-Mail senden")

Die HYPERLINK-Formel besteht aus den folgenden Teilen:

Hyperlink_Adresse

Hyperlink_Adresse ist der erste Teil der Formel. In diesem Beispiel werden mailto, subject und body festgelegt.

Mail an

Der Teil „mailto:“ der Formel legt den E-Mail-Empfänger fest. Dies muss eine gültige E-Mail-Adresse sein, die in die Formel eingegeben wird, oder, wie in diesem Beispiel, mit einer Zelle (C3) verknüpft ist, die eine gültige E-Mail-Adresse enthält.

"mailto:" & C4

Betreff

„?subject=“ kann Text zwischen dem Gleichheitszeichen und Anführungszeichen enthalten, mit einer Zelle verknüpft sein oder eine Formel enthalten. In diesem Beispiel gibt es eine Formel, um den Status einer Bestellung zu überprüfen. Wenn der Status 1 ist, verwenden Sie „Vielen Dank für Ihre Bestellung“ aus Zelle I3.

Verwenden Sie dazu die folgende WENN-Anweisung für den Betreff-Teil der Formel.

"?subject="&WENN(D4=1;$I$3;WENN(D4=2;$I$4;$I$5))

Beachten Sie, dass vor dem Wort „subject“ das Symbol ? stehen muss

CC

Wenn Sie Ihrer E-Mail ein CC hinzufügen möchten, fügen Sie es in die Formel nach dem Betreff in Anführungszeichen ein. Sie benötigen ein kaufmännisches Und (&) vor dem „cc.“. Sie können entweder die E-Mail-Adresse eingeben, um das CC in mailto zu setzen, oder Sie können es mit einer externen Zelle, wie bei der Betreffzeile und dem Text der E-Mail, verknüpfen.

"&cc=abclimited@abc.com"

Rumpf

Der Teil „&body=“ der Formel kann zusätzlichen Text vor dem schließenden Anführungszeichen enthalten. Sie können auch eine angepasste WENN-Anweisung mit einer Formel erstellen:

"&body="&WENN(D5=1;$J$3;WENN(D5=2;$J$4;$J$5&E5)) & " " &$J$7

Diese WENN-Anweisung prüft den Status der Bestellung und fügt dann am Ende des E-Mail-Rumpfes eine Nachricht hinzu (Vielen Dank für Ihren Einkauf!).

Wie beim CC brauchen Sie ein kaufmännisches Und (&) vor dem Wort „body“.

Die Nachricht (in Zelle J7) enthält am Ende den Text:

"%0A%0A Vielen Dank für Ihre Bestellung! %0A %0A mit freundlichen Grüßen%0A ABC Limited"

wobei das „%0A“ Leerzeilen einfügt. Der Text in der E-Mail wird dann wie folgt angezeigt:

Hinweis: Die Zellen, die sich auf die Suchspalten (für den Betreff und den Rumpf ) beziehen, wurden als absolute (oder „gesperrte“) Zellenadressen in die Formel eingefügt. Auf diese Weise können Sie die Formel in die übrigen Bestellungsdatensätze kopieren.

Freundlicher Name

Der letzte Teil der Formel ist der Text, der in der mit einem Hyperlink versehenen Zelle in Excel angezeigt wird. Dies ist der Text, auf den Sie klicken, um die E-Mail zu erstellen. In diesem Beispiel wird der Text „E-Mail senden“ verwendet, es kann aber jeder beliebige Text eingegeben werden, solange er in Anführungszeichen steht.

Zeigen Sie die Formel im Dialogfeld „Funktionsargumente“, indem Sie auf die Formel und dann auf das Feld „Funktion einfügen“ in der Formelleiste klicken.

Hyperlink_Adresse und Freundlicher_Name werden in den Funktionsargumenten angezeigt.

Daher erzeugt die Formel:

=HYPERLINK("mailto:" & C3 & "?subject="&WENN(D3=1;$I$3;WENN(D3=2;$I$4;$I$5)) &"&cc=abclimited@abc.com"&"&body="&WENN(D3=1;$J$3;WENN(D3=2;$J$4;$J$5&E3)) & " " &$J$7; "E-Mail senden")

diese E-Mail:

Formel nach unten kopieren

Da die Formel absolute Zellenadressen verwendet, um auf die Nachschlagezellen für Betreff und Rumpf zu verweisen, müssen Sie die gesamte Formel nur einmal eingeben. Kopieren Sie dann die erste Zelle nach unten in die restlichen Zeilen Ihres Bereichs.

Klicken Sie auf einen der Hyperlinks mit dem Anzeigetext „E-Mail senden“, um eine benutzerdefinierte E-Mail an den Kunden zu senden.