BUSCARV – Valores Duplicados – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial mostrará cómo buscar valores duplicados utilizando BUSCARV en Excel y Google Sheets. Si su versión de Excel admite BUSCARX, le recomendamos que utilice BUSCARX en su lugar, ya que esto permite una solución mucho más fácil..
BUSCARV Enésima coincidencia
La función BUSCARV siempre devuelve la primera coincidencia. Para devolver valores duplicados (o la enésima coincidencia) necesitamos:
- Un nuevo identificador único para diferenciar todos los valores duplicados.
- Una columna de ayuda que contiene una lista de identificadores únicos que servirá como la nueva columna de búsqueda (primera columna) de la matriz de la tabla.
- Un valor de búsqueda modificado para que coincida con el formato de los identificadores únicos.
La solución final será así:
=BUSCARV(F3&"-"&G3;B3:D7;3;FALSO)
Ahora, vamos a ver la solución:
IDs únicos usando CONTAR.SI
Digamos que queremos buscar la segunda puntuación para el ID de estudiante = 2021-A en este conjunto de datos:
Primero, crearemos IDs únicos en la columna B uniendo el ID original del estudiante (columna C) con una función CONTAR.SI:
=C3&"-"&CONTAR.SI($C$3:C3;C3)
La función CONTAR.SI cuenta el número de cada ID de estudiante. Al bloquear una referencia de celda en la Función CONTAR.SI, pero no la otra, identificamos cada instancia de un ID de estudiante duplicado con un número único:
=CONTAR.SI($C$3:C3;C3)
Luego simplemente usamos la operación & para concatenar todo junto como en la fórmula anterior.
BUSCARV Enésima Coincidencia
Ahora, podemos hacer un BUSCARV de la segunda coincidencia utilizando esta fórmula en la que el valor de la búsqueda coincide con el formato del nuevo ID único:
=BUSCARV(F3&"-"&G3;B3:D7;3;FALSO)
BUSCARV Todas las Coincidencias
En cambio, ¿qué pasa si quiere buscar todas las coincidencias? Podría enumerar manualmente cada una de las coincidencias que desea encontrar:
Esta podría ser una solución aceptable, pero ¿qué pasa si no sabe cuántas coincidencias existen? Esta fórmula mostrará todas las coincidencias para «2021-A»:
=SI.ND(BUSCARV($F$2&"-"&FILA(1:1);$B$3:$D$7;3;FALSO);"")
Repasemos la fórmula anterior:
Función FILA
Utilizamos la Función FILA para devolver el número de fila de una celda o de un rango. Si queremos una fórmula que pueda crear una lista de números de conteo consecutivos empezando por el 1, podemos introducir una referencia de fila completa en la Función FILA y copiarla y pegarla en la columna.
=FILA(1:1)
Nuevo valor de búsqueda
A continuación, utilice el resultado de la Función FILA se combina con el valor de búsqueda (Columna G Encabezado) para crear su valor de búsqueda único.
=$G$2&"-"&F3
Nota: Asegúrese de que el valor de búsqueda original está en referencia absoluta (por ejemplo, $G$2).
Función BUSCARV
A continuación, realice el BUSCARV:
=BUSCARV(G3;$B$3:$D$7;3;FALSO)
Función SI.ND
Observa los errores #N/D para los valores que no existen. A continuación, utilicemos la función SI.ND para obtener una salida en blanco:
=SI.ND(H3;"")
Combinando todas las funciones se obtiene nuestra fórmula original:
=SI.ND(BUSCARV($F$2&"-"&FILA(1:1);$B$3:$D$7;3;FALSO);"")Hay una solución más cómoda y sencilla que la fórmula anterior, y es utilizando la nueva Función FILTRO. Podemos utilizar la Función FILTRO para filtrar los datos y extraer los duplicados de una sola vez, pero esta función actualmente sólo está disponible para la versión de Microsoft 365. Si tienes Microsoft 365, entonces debes usar la Función XLOOKUP en su lugar.
BUSCARV Duplicar valores de búsqueda
Ahora, ¿qué pasa si queremos hacer coincidir los valores de búsqueda duplicados con sus correspondientes instancias de la columna de búsqueda? En este caso, aplicamos el mismo método de las secciones anteriores al valor de búsqueda:
=BUSCARV(F3&"-"&CONTAR.SI($F$3:F3;F3);$B$3:$D$7;3;FALSO)
BUSCARV Enésima coincidencia en Google Sheets
Todas las fórmulas BUSCARV que hemos comentado anteriormente funcionan de la misma manera en Google Sheets.
=BUSCARV(F3&"-"&G3;B3:D7;3;FALSO)
