BUSCARX Multiples Criterios
Descargar el Libro de Ejemplo
Este tutorial demostrará cómo realizar un BUSCARX con múltiples criterios en Excel. Si su versión de Excel no soporta BUSCARX, lea cómo utilizar BUSCARV en su lugar.
BUSCARX Concatenación de Múltiples Criterios
Una forma común de realizar un BUSCARX de múltiples criterios es concatenando todos los criterios en un valor de búsqueda y sus correspondientes columnas de búsqueda en una matriz de búsqueda.
=BUSCARX(F3&G3;B3:B7&C3:C7;D3:D7)
Veamos la fórmula:
Concatenar las columnas de búsqueda
En primer lugar, concatenamos las columnas de búsqueda para crear una matriz de identificadores únicos, lo que nos permite buscar todos los criterios simultáneamente.
=B3&C3
Concatenar los criterios
A continuación, hacemos lo mismo con los criterios para crear un nuevo valor de búsqueda.
=F3&G3
Función BUSCARX
Por último, suministramos el nuevo valor de búsqueda y la matriz de búsqueda a la función BUSCARX.
=BUSCARX(K3;I3:I7;D3:D7)
Si lo unimos todo, obtenemos la fórmula original:
=BUSCARX(F3&G3;B3:B7&C3:C7;D3:D7)BUSCARX Múltiples Criterios Expresiones Booleanas
Otra opción es crear expresiones booleanas en las que los criterios se comprueban con sus correspondientes columnas de búsqueda.
=BUSCARX(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
Veamos esta fórmula:
Expresiones booleanas
En primer lugar, apliquemos los criterios adecuados a sus correspondientes columnas utilizando los operadores lógicos (por ejemplo, =,<,>). Comencemos con el primer criterio (por ejemplo, ID de estudiante).
=B3=$F$3
Repitamos el paso para los otros criterios (por ejemplo, la asignatura).
=C3=$G$3
Array Y
A continuación, realizamos el equivalente de la función Y multiplicando las matrices booleanas donde VERDADERO es 1 y FALSO es 0.
=I3*J3
Nota: La función Y es una función agregada (muchas entradas para una salida). Por lo tanto, no podemos usarla en cálculos de matrices.
Función BUSCARX
A continuación, buscamos el 1 del resultado del Array Y.
=BUSCARX(1;K3:K7;D3:D7)
Combinando todas las fórmulas obtenemos nuestra fórmula original:
=BUSCARX(1;(B3:B7=F3)*(C3:C7=G3);D3:D7)
