Extraer la Última Palabra en Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial demostrará cómo extraer la última palabra de una celda en Excel y Google Sheets.
Extraer la última palabra
Si quisiéramos extraer la primera palabra de una celda podríamos utilizar simplemente la función ENCONTRAR para encontrar el primer espacio y la función IZQUIERDA para obtener la palabra anterior al espacio. Desafortunadamente, Excel no tiene una Función ENCONTRAR inversa, así que tendremos que desarrollar una solución diferente:
- Utilice la Función SUSTITUIR para reemplazar los espacios entre las palabras con un gran número (n) de espacios.
- Utilice la Función DERECHA para calcular el número n de espacios correcto. (Esto incluirá nuestra palabra, así como un número de espacios adicionales)
- Utilice la Función ESPACIOS para recortar los espacios adicionales, dejando sólo la última palabra.
Esta es la fórmula que utilizaremos:
=ESPACIOS(DERECHA(SUSTITUIR(B3;" ";REPETIR(" ";10));10))
Observa que para este ejemplo elegimos n=10. Este número es demasiado pequeño: la celda C6 no contiene la última palabra completa porque la palabra tiene 11 caracteres. Hemos elegido un número pequeño para fines de demostración, pero le recomendamos que utilice un número mucho mayor (por ejemplo, 99) o que utilice la fórmula versátil que se encuentra al final de este tutorial. Ahora veamos la fórmula:
Función REPETIR
La función REPETIR repite un carácter (n) un número de veces. Esta fórmula generará 10 espacios:
=REPETIR("-";10)Aquí, para mostrar que esta función funcionará, hemos sustituido los espacios en blanco por guiones (-):
Función SUSTITUIR
La función SUSTITUIR encuentra todos los espacios en blanco en la cadena de texto y reemplaza los espacios en blanco por 10 espacios.
=SUSTITUIR(B3;" ";C3)
Función DERECHA
La función DERECHA extrae los últimos 10 caracteres de la celda:
=DERECHA(D3;10)
Función ESPACIOS
La función ESPACIOS elimina todos los espacios iniciales y finales del texto y devuelve sólo la última palabra:
=ESPACIOS(E3)
Fórmula versátil
En lugar de definir el número (n), puede utilizar la función LARGO para calcular n como el número de caracteres de la celda. Esta fórmula funcionará independientemente del tamaño de la última palabra.
=ESPACIOS(DERECHA(SUSTITUIR(B3;" ";REPETIR(" ";LARGO(B3)));LARGO(B3)))
Extraer la última palabra en Google Sheets
La fórmula para extraer la última palabra de un texto funciona exactamente igual en Google Sheets que en Excel:
