Fórmula MEDIANA SI – Excel y Google Sheets

Este tutorial demostrará cómo calcular el valor de la mediana que cumple ciertos criterios en Excel y Google Sheets.

 

Función MEDIANA

La función MEDIANA calcula el valor de la mediana.

=MEDIANA(C2:C10)

 

Sin embargo, no existe una función «Mediana Si» incorporada para calcular el valor de la mediana sólo para los números que cumplen ciertos criterios.

Nota: Puede que esté familiarizado con la función PROMEDIO.SI.CONJUNTO, que calcula la media de los números que cumplen ciertos criterios. No hay una alternativa a la mediana.

Mediana Si – Fórmula de Array

Entonces, para calcular la «Mediana Si», debemos utilizar una Fórmula Array con la Función SI dentro de la Función MEDIANA:

=MEDIANA(SI($A$2:$A$10=$E2; $C$2:$C$10))

 

Vamos a recorrer esta fórmula….

Excel 2019 y versiones anteriores

En Office 365 y en las versiones de Excel posteriores a 2019, puedes simplemente introducir la fórmula anterior como lo harías normalmente (pulsando ENTER). Sin embargo, para Excel 2019 y versiones anteriores, debes introducir la fórmula pulsando CTRL + SHIFT + ENTER. Después de hacerlo, notarás que aparecen corchetes alrededor de la fórmula:

{=MEDIANA(SI($A$2:$A$10=$E2; $C$2:$C$10))}

Importante: no escriba estas llaves usted mismo, sólo debe introducirlas con CTRL + SHIFT + ENTER.

¿Cómo funciona la fórmula?

Recuerda que esta es nuestra fórmula

{=MEDIANA(SI($A$2:$A$10=$E2; $C$2:$C$10))}

La fórmula funciona evaluando los criterios de cada valor como VERDADERO o FALSO.

=MEDIANA(SI({FALSO;VERDADERO;FALSO;FALSO;VERDADERO;FALSO;VERDADERO;VERDADERO;FALSO}; {1287;1205;1243;1482;1261;1042;1090;1748;1909}))

La función SI sustituye VERDADERO por los valores reales.

=MEDIANA({FALSO;1205;FALSO;FALSO;1261;FALSO;1090;1748;FALSO})

Ahora la Función MEDIANA ignora los valores FALSOS y calcula la mediana de los valores restantes (1233 es la media de los dos valores medios: 1205 y 1261).

Mediana SI – Criterios múltiples

También puede calcular una mediana basada en múltiples criterios utilizando la lógica booleana. Echemos un vistazo a un nuevo conjunto de datos con las columnas Ubicación, Año y Stock:

 

Esta es la fórmula para calcular la mediana basada en múltiples criterios:

=MEDIANA(SI((A2:A4="B")*(B2:B4=2008);C2:C4))

 

Observe que aquí multiplicamos dos conjuntos de criterios juntos:

(A2:A4="b")*(B2:B4=2008)

Si ambos criterios son VERDADERO, se calculará como VERDERO, pero si uno (o más) de los criterios es FALSO, se calculará como FALSO.

Fórmula MEDIANA SI  en Google Sheets

Todos los ejemplos anteriores funcionan igual en Google Sheets, excepto que tu fórmula debe estar contenida dentro de la función ARRAYFORMULA (porque es una fórmula de matriz).

=ARRAYFORMULA(MEDIANA(SI($A$2:$A$10=$G2; $C$2:$C$10)))