Separar Nombres y Apellidos – Excel y Google Sheets
Descargar el Libro de Ejemplo
Este tutorial mostrará cómo separar el nombre y el apellido en Excel y Google Sheets.
Separar el Nombre
En primer lugar, para separar el nombre del apellido, podemos utilizar las funciones IZQUIERDA y HALLAR.
=IZQUIERDA(B3; HALLAR(" "; B3))
Separar el Apellido
A continuación, utilizamos las funciones HALLAR y EXTRAE para obtener el apellido.
=EXTRAE(B3;HALLAR(" ";B3)+1;999)
A continuación veremos cómo hacerlo.
Función HALLAR (Nombre)
En primer lugar, utilizamos la Función HALLAR para encontrar la posición del espacio entre el nombre y el apellido.
=HALLAR(" ";B3)+1
Función IZQUIERDA (Nombre)
A continuación, utilizamos la función IZQUIERDA para obtener los caracteres anteriores al espacio (el nombre):
=IZQUIERDA(B3;C3)
Combinando estas funciones se obtiene la fórmula original para el nombre:
=IZQUIERDA(B3; HALLAR(" "; B3))
A continuación veremos cómo extraer el apellido.
En la siguiente sección, utilizaremos las funciones HALLAR y EXTRAE para extraer caracteres del centro de una cadena de texto.
Función HALLAR (Apellido)
En primer lugar, utilizamos la Función HALLAR para encontrar la posición del espacio entre el nombre y el apellido.
=HALLAR(" ";B3)
A continuación, sumamos uno al valor devuelto por esta fórmula para obtener la posición inicial del apellido.
Función EXTRAE (Apellido)
A continuación utilizamos la Función EXTRAE para obtener todos los caracteres después del espacio más 1 (el apellido)
=EXTRAE(B3; C3+1; 999)Combinando estas 2 funciones obtenemos la fórmula original para el apellido.
=EXTRAE(B3;HALLAR(" ";B3)+1;999)
Segundo Nombre
A continuación veremos cómo separar los nombres que incluyen segundos nombres o iniciales.
El cálculo para el nombre de pila no cambia.
Para extraer un segundo nombre o inicial de un nombre, necesitaríamos utilizar las funciones DERECHA, HALLAR y LARGO para obtener el apellido de la cadena de nombre. También vamos a incorporar la Función ESPACIOS para recortar los espacios a ambos lados de la cadena de texto.
=DERECHA(B4;LARGO(B4)-HALLAR(" ";B4)-LARGO(ESPACIOS(EXTRAE(B4;
HALLAR(" ";B4;1)+1;HALLAR(" ";B4;HALLAR(" ";B4;1)+1)-HALLAR(" ";B4;1))))-1)
Esta fórmula sólo funcionará si hay más de un espacio en la cadena de texto. Si sólo hay un espacio, se devolverá un error con #VALOR.
Para resolver este problema, para nombres sin segundo nombre o iniciales, podemos utilizar la fórmula original usando las funciones EXTRAE y HALLAR.
Luego podríamos combinar las 2 fórmulas usando la Función SI.ERROR.
=SI.ERROR(DERECHA(B3;LARGO(B3)-HALLAR(" ";B3)-LARGO(ESPACIOS(EXTRAE(B3;HALLAR(" ";B3;1)+1;
HALLAR(" ";B3;HALLAR(" ";B3;1)+1)-HALLAR(" ";B3;1))))-1);EXTRAE(B3;HALLAR(" ";B3)+1;999))
A continuación, podríamos utilizar las funciones EXTRAE y LARGO para obtener el segundo nombre o la inicial.
=EXTRAE(B3;LARGO(C3)+1;LARGO(B3)-LARGO(C3&D3))
Separar Nombres y Apellidos en Google Sheets
Todos los ejemplos explicados anteriormente funcionan igual en Google Sheets que en Excel.
