Extraire le Dernier Mot dans Excel et Google Sheets
Télécharger le Classeur Exemple
Ce tutoriel montre comment extraire le dernier mot d’une cellule dans Excel et Google Sheets.
Extraire le Dernier Mot
Si nous souhaitons extraire le premier mot d’une cellule nous pourrions simplement utiliser la fonction CHERCHE pour trouver le premier espace et la fonction GAUCHE pour afficher le mot qui précède l’espace.
Malheureusement, Excel ne dispose pas d’une fonction CHERCHE inverse. Nous devrons donc développer une autre solution :
- Utilisez la fonction SUBSTITUE pour remplacer les espaces entre les mots par un grand nombre (n) d’espaces.
- Utilisez la fonction DROITE pour calculer le bon nombre n d’espaces. (Cela comprendra notre mot, ainsi qu’un certain nombre d’espaces supplémentaires)
- Utilisez la fonction SUPPRESPACE pour supprimer les espaces supplémentaires et ne laisser que le dernier mot.
Voici la formule que nous utiliserons :
=SUPPRESPACE(DROITE(SUBSTITUE(B6;" ";REPT(" ";10));10))
Remarquez que pour cet exemple, nous choisissons n=10. Ce nombre est trop petit : la cellule C6 ne contient pas le dernier mot complet car le mot comporte 14 caractères.
Nous avons choisi un petit nombre à des fins de démonstration, mais nous vous recommandons d’utiliser un nombre beaucoup plus grand (ex. 99) ou d’utiliser la formule polyvalente que vous trouverez à la fin de ce tutoriel.
Passons maintenant à la formule :
Fonction REPT
La fonction REPT répète un caractère un certain nombre (n) de fois. Cette formule générera 10 espaces :
=REPT(" ";10)Ici, pour montrer le fonctionnement de cette fonction, nous avons remplacé les espaces vides par des tirets (-) :
Fonction SUBSTITUE
La fonction SUBSTITUE trouve tous les espaces vides dans la chaîne de texte et remplace les espaces vides par 10 espaces.
=SUBSTITUE(B3;" ";C3)
Fonction DROITE
La fonction DROITE extrait les 10 derniers caractères de la cellule :
=DROITE(D3;10)
Fonction SUPPRESPACE
La fonction SUPPRESPACE supprime tous les espaces avant et après le texte et ne renvoie que le dernier mot :
=SUPPRESPACE(E3)
Formule Dynamique
Au lieu de définir le nombre (n), vous pouvez utiliser la fonction NBCAR pour spécifier n égal au nombre de caractères dans la cellule. Cette formule fonctionnera quelle que soit la taille du dernier mot.
=SUPPRESPACE(DROITE(SUBSTITUE(B3;" ";REPT(" ";NBCAR(B3)));NBCAR(B3)))
Extraction du Dernier Mot dans Google Sheets
La formule permettant d’extraire le dernier mot d’un texte fonctionne exactement de la même manière dans Google Sheets et dans Excel :
