Formules GRANDE.VALEUR SI et PETITE.VALEUR SI dans Excel et Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

David Gagnon

Last updated on février 5, 2023

Download Example Workbook

Télécharger le Classeur Exemple

Ce tutoriel montre comment calculer un « grande.valeur si » ou un « petite.valeur si », en récupérant la nième valeur la plus grande (ou la plus petite) en fonction de certains critères.

grande valeur petite valeur fonction principale

Fonctions GRANDE.VALEUR et PETITE.VALEUR

La fonction GRANDE.VALEUR est utilisée pour calculer la nième plus grande valeur (k) d’un tableau, tandis que la fonction PETITE VALEUR renvoie la nième plus petite valeur.

=GRANDE.VALEUR($D$2:$D$10;1)

fonction grande valeur exemple simple

Pour créer une fonction « GRANDE.VALEUR SI », nous allons utiliser la fonction GRANDE.VALEUR avec la fonction SI dans une formule de tableau.

GRANDE.VALEUR SI

En combinant GRANDE.VALEUR (ou PETITE VALEUR) et SI dans une formule de tableau, nous pouvons essentiellement créer une fonction « GRANDE.VALEUR SI » qui fonctionne de la même manière que la fonction SOMME.SI intégrée. Prenons un exemple.

Nous avons une liste de notes obtenues par des étudiants dans deux matières différentes :

grande valeur petite valeur donnees entrees exemple

Supposons que l’on nous demande de trouver les trois meilleures notes obtenues pour chaque matière, comme suit :

grande valeur petite valeur exemple resultats meilleures notes

Pour ce faire, nous pouvons imbriquer une fonction SI avec la matière comme critère à l’intérieur de la fonction GRANDE.VALEUR comme suit :

=GRANDE.VALEUR(SI(<plage critère>=<critère>; <plage valeurs>);<position>)

=GRANDE.VALEUR(SI($C$2:$C$10=$F3;$D$2:$D$10);G$2)

Lorsque vous utilisez Excel 2019 et les versions antérieures, vous devez saisir la formule en appuyant sur CTRL + MAJ + ENTRÉE pour obtenir les accolades autour de la formule.

Comment Fonctionne cette Formule ?

La formule fonctionne en évaluant chaque cellule de notre plage de critères comme VRAI ou FAUX. Trouver la valeur de la meilleure note (k=1) en Math :

=GRANDE.VALEUR(SI($C$2:$C$10=$F3;$D$2:$D$10);G$2)

=GRANDE.VALEUR(SI({VRAI; FAUX; FAUX; VRAI; FAUX; VRAI; FAUX; VRAI; FAUX}, {0,81 ; 0,8 ; 0,93 ; 0,42 ; 0,87 ; 0,63 ; 0,71 ; 0,58 ; 0,73}), 1)

Ensuite, la fonction SI remplace chaque valeur par FAUX si sa condition n’est pas remplie.

=GRANDE.VALEUR({0.81;FAUX;FAUX;0.42;FAUX;0.63;FAUX;0.58;FAUX},1)

Maintenant, la fonction GRANDE.VALEUR ignore les valeurs FAUX et calcule la plus grande (k=1) des valeurs restantes (0,81 est la plus grande valeur entre 0,42 et 0,81).

SI PETITE VALEUR

La même technique peut également être appliquée avec la fonction PETITE.VALEUR.

=PETITE.VALEUR(SI($C$2:$C$10=$F3,$D$2:$D$10),G$2)

GRANDE.VALEUR SI avec Plusieurs Critères

Pour utiliser la fonction GRANDE.VALEUR SI avec plusieurs critères (de la même manière que la formule SOMME.SI.ENS intégrée), il suffit d’imbriquer plusieurs fonctions SI dans la fonction GRANDE.VALEUR, comme suit :

=GRANDE.VALEUR(SI(<plage critère1>=<critère1>; SI(<plage critère2>=<critère2>; <plage valeurs>));<position>)

=GRANDE.VALEUR(SI($D$2:$D$18=$H3;SI($B$2:$B$18=$G3;$E$2:$E$18));I$2)

grande valeur petite valeur fonction si plusieurs criteres

Une autre façon d’inclure plusieurs critères est de les multiplier ensemble, comme le montre cet article sur le calcul de la médiane.

Conseils et Astuces :

Dans la mesure du possible, référencez toujours la position (k) à partir d’une cellule d’aide et verrouillez la référence (F4), car cela facilitera le remplissage automatique des formules.
Si vous utilisez Excel 2019 ou une version plus récente, vous pouvez saisir la formule sans CTRL + MAJ + ENTRÉE.
Pour retrouver les noms des étudiants qui ont obtenu les meilleures notes, combinez cette formule avec INDEX / EQUIV.