RECHERCHEV – Plusieurs Feuilles à la Fois – Excel et Google Sheets
Télécharger le Classeur Exemple
Ce tutoriel montre comment effectuer une RECHERCHEV sur plusieurs feuilles dans Excel et Google Sheets. Si votre version d’Excel prend en charge RECHERCHEX, nous vous recommandons d’utiliser RECHERCHEX à la place.
La fonction RECHERCHEV ne peut effectuer une consultation que sur un seul ensemble de données. Si nous voulons effectuer une consultation parmi plusieurs ensembles de données stockés dans des feuilles différentes, nous pouvons soit combiner tous les ensembles de données en un seul ensemble, soit utiliser la fonction SIERREUR avec RECHERCHEV pour effectuer plusieurs consultations dans une seule formule.
Cette dernière méthode est plus simple dans Excel, tandis que la première est plus simple dans Google Sheets.
RECHERCHEV avec SIERREUR
La fonction RECHERCHEV (et d’autres formules de consultation) renvoie une erreur si elle ne trouve pas de correspondance, et nous utilisons normalement la fonction SIERREUR pour remplacer l’erreur par une valeur personnalisée.
Au lieu d’une valeur personnalisée, nous allons utiliser la fonction SIERREUR pour effectuer une autre RECHERCHEV à partir d’une autre feuille si la première RECHERCHEV ne trouve pas de correspondance dans la première feuille.
RECHERCHEV – 2 Feuilles à la Fois
=SIERREUR(RECHERCHEV(B3;'Dept. A'!$B$3:$C$7;2;FAUX);RECHERCHEV(B3;'Dept. B'!$B$3:$C$7;2;FAUX))
Passons en revue la formule :
Fonction RECHERCHEV
Voici la première RECHERCHEV:
=RECHERCHEV(B3;'Dept. A'!$B$3:$C$7;2;FAUX)
Remarque : La fonction RECHERCHEV recherche la valeur de recherche dans la première colonne de la table et renvoie la valeur correspondante de la colonne définie par l’index de colonne spécifié (c’est-à-dire le troisième argument). Le dernier argument définit le type de correspondance (c.-à-d., Vrai – Correspondance approximative, Faux – Correspondance exacte).
Voici la RECHERCHEV pour la 2ème feuille :
=RECHERCHEV(B3;'Dept. B'!$B$3:$C$7;2;FAUX)
Fonction SIERREUR
Nous avons combiné les résultats des 2 RECHERCHEV en utilisant la fonction SIERREUR.
Nous vérifions la valeur de la première RECHERCHEV (par exemple, Département A). Si une valeur est une erreur, la valeur correspondante de la 2ème RECHERCHEV est retournée à la place.
=SIERREUR(E3;F3)
Remarque : La fonction SIERREUR vérifie une valeur (c’est-à-dire le 1er argument) si elle est erronée (par exemple, #N/A, #REF !). Si c’est une erreur, elle renvoie la valeur de son dernier argument au lieu de l’erreur. S’il ne s’agit pas d’une erreur, il renverra la valeur qui est en train d’être vérifiée.
En combinant tous ces concepts, on obtient notre formule originale :
=SIERREUR(RECHERCHEV(B3;'Dept. A'!$B$3:$C$7;2;FAUX);RECHERCHEV(B3;'Dept. B'!$B$3:$C$7;2;FAUX))RECHERCHEV – Plus de 2 Feuilles à la Fois
Pour plus de deux feuilles, nous devons ajouter une RECHERCHEV et un SIERREUR par feuille supplémentaire à la formule ci-dessus. Voici la formule pour 3 feuilles :
=SIERREUR(SIERREUR(RECHERCHEV(B3;'Dept. A'!$B$3:$C$7;2;FAUX);RECHERCHEV(B3;'Dept. B'!$B$3:$C$7;2;FAUX));RECHERCHEV(B3;'Dept. C'!$B$3:$C$7;2;FAUX))
RECHERCHEV – Plusieurs Feuilles à la Fois dans Google Sheets
Bien que la combinaison de IFERROR et VLOOKUP fonctionne de la même manière dans Google Sheets, il est plus simple de combiner les ensembles de données en un seul.
RECHERCHEV avec des Accolades {} (Google Sheets)
Nous pouvons combiner les ensembles de données en un seul en utilisant les accolades.
=RECHERCHEV(B3 ;{'Dept. A'!$B$3:$C$7 ; 'Dept. B'!$B$3:$C$7 ; 'Dept. C'!$B$3:$C$7};2;FAUX )
Décomposons et visualisons la formule : Empilez tous les ensembles de données verticalement en séparant les plages de cellules à l’aide du point-virgule à l’intérieur des accolades :
={'Dept. A'!$B$3:$C$7 ; 'Dept. B'!$B$3:$C$7 ; 'Dept. C'!$B$3:$C$7}
Remarque : les accolades dans Google Sheets peuvent également être utilisées pour créer un tableau à partir de plages de cellules. Le point-virgule est utilisé pour empiler les valeurs verticalement tandis que la virgule est utilisée pour empiler les valeurs horizontalement. Si les plages de cellules sont empilées verticalement, nous devons nous assurer que le nombre de colonnes est le même pour chacune des plages de cellules. Sinon, cela ne fonctionnera pas. Pour l’horizontale, le nombre de lignes doit être le même.
Le tableau résultant est utilisé comme entrée pour le 2ème argument de la RECHERCHEV :
=RECHERCHEV(E3;$B$3:$C$17;2;FAUX)
En combinant tous ces éléments, on obtient notre formule originale :
=RECHERCHEV(B3 ;{'Dept. A'!$B$3:$C$7 ; 'Dept. B'!$B$3:$C$7 ; 'Dept. C'!$B$3:$C$7};2;FAUX )
