VLOOKUP Renvoie 0? Renvoyer un Blanc à la Place – Excel et Google Sheets

Ce tutoriel montre comment renvoyer un blanc si la sortie de RECHERCHEV est vide. Si votre version d’Excel prend en charge la fonction RECHERCHEX, nous vous recommandons d’utiliser RECHERCHEX à la place.

Dans Excel, lorsque vous faites référence à une autre cellule avec une formule, les valeurs vides sont calculées comme zéro.

Cela peut poser un problème dans certains scénarios de RECHERCHEV où nous devons distinguer les espaces blancs des zéros :

=RECHERCHEV("2021-D";B3:C7;2;FAUX)

 

RECHERCHEV avec SI et ESTVIDE

Nous pouvons utiliser la combinaison de RECHERCHEV avec SI et ESTVIDE pour résoudre ce problème :

=SI(ESTVIDE(RECHERCHEV(E3;B3:C7;2;FAUX));"";RECHERCHEV(E3;B3:C7;2;FAUX))

Décomposons et analysons cette formule :

Pour retourner un espace blanc si la sortie de RECHERCHEV est vide, nous avons besoin de deux choses :

1. Une méthode pour vérifier si la sortie de RECHERCHEV est vide
2. Et une fonction qui peut remplacer le zéro par une chaîne vide («  »), qui est la valeur la plus proche d’un espace blanc que nous puissions retourner.

 

Fonction ESTVIDE

Nous pouvons utiliser ESTVIDE pour vérifier si le résultat de RECHERCHEV est vide.

=ESTVIDE(RECHERCHEV(E3;B3:C7;2;FAUX))

 

Notes :

1. La fonction ESTVIDE renvoie VRAI si une valeur est vide. La chaîne vide («  ») et le 0 ne sont pas équivalents à un blanc. Une cellule contenant une formule n’est pas vide, c’est pourquoi nous ne pouvons pas utiliser F3 comme entrée pour la fonction ESTVIDE.
2. Les formules peuvent renvoyer des blancs, mais ils sont convertis en zéro à l’étape finale du calcul.
3. Par conséquent, nous pouvons imbriquer des formules dans ESTVIDE pour vérifier si leurs résultats sont des blancs plutôt que d’affecter les formules aux cellules avant d’appliquer ESTVIDE aux cellules.

 

Fonction SI

Nous pouvons ensuite utiliser la fonction SI pour tester si la combinaison de ESTVIDE et RECHERCHEV est VRAI ou FAUX. Nous pouvons définir un processus quelconque (par exemple, sortir une chaîne vide) si la condition est VRAIE et un autre (par exemple, le résultat de RECHERCHEV s’il n’est pas vide) si le résultat est FAUX.

=SI(G3;"";F3)

En combinant tous ces concepts, on obtient notre formule originale :

=SI(ESTVIDE(RECHERCHEV(E3;B3:C7;2;FAUX));"";RECHERCHEV(E3;B3:C7;2;FAUX))

RECHERCHEV avec SI et Chaîne Vide («  »)

Nous pouvons utiliser la chaîne vide comme critère pour vérifier si la valeur de RECHERCHEV est vide au lieu d’utiliser la fonction ESTVIDE :

=SI(RECHERCHEV(E3;B3:C7;2;FAUX)="";"";RECHERCHEV(E3;B3:C7;2;FAUX))

Remarque : Un blanc peut être équivalent à un zéro ou à une chaîne vide selon le calcul, mais les chaînes vides et les 0 ne sont pas des blancs.

RECHERCHEV avec SI et NBCAR

Une autre alternative à ESTVIDE est l’utilisation de la fonction NBCAR:

=SI(NBCAR(RECHERCHEV(E3;B3:C7;2;FAUX))=0;"";RECHERCHEV(E3;B3:C7;2;FAUX))

Examinons de plus près cette solution alternative :

Vérification d’un Blanc à l’Aide de NBCAR

Comme indiqué précédemment, les formules renvoient des résultats vides mais sont converties à la fin des calculs.

Par conséquent, nous pouvons utiliser la fonction NBCAR pour compter le nombre de caractères de la sortie de RECHERCHEV :

=NBCAR(RECHERCHEV(E3;B3:C7;2;FAUX))

 

Si le nombre de caractères est égal à 0, cela signifie que la valeur est vide. Nous pouvons alors utiliser la fonction SI pour vérifier si la fonction LEN est égale à 0, et retourner une chaîne vide si c’est vrai :

=SI(G3=0;"";F3)

 

En combinant tous ces concepts, on obtient notre formule originale :

=SI(NBCAR(RECHERCHEV(E3;B3:C7;2;FAUX))=0;"";RECHERCHEV(E3;B3:C7;2;FAUX))

RECHERCHEV Renvoie un Blanc dans Google Sheets

Toutes les formules mentionnées précédemment fonctionnent de la même manière dans Google Sheets. En fait, nous n’avons pas besoin de les implémenter dans Google Sheets pour afficher un résultat semblable à un blanc, car Google Sheets peut renvoyer des blancs.

Remarque : cela est très utile dans les scénarios où nous devons distinguer les blancs des chaînes de caractères vides.

Notez que les formules ci-dessus ne sont applicables que si la sortie est vide, ce qui est différent d’un résultat « sans correspondance ». Si RECHERCHEV ne trouve pas de correspondance, il renvoie l’erreur #N/A à la place, et dans ce cas, nous devons gérer l’erreur #N/A ; veuillez consulter l’article : « RECHERCHEV – Gestion des Erreurs #NA »