Somme et Somme Si avec RECHERCHEV – Excel et Google Sheets

Written by

Editorial Team

Reviewed by

Steve Rynearson

Translated by

David Gagnon

Last updated on février 5, 2023

Download Example Workbook

Télécharger le Classeur Exemple

Ce tutoriel montre comment utiliser la fonction RECHERCHEV imbriquée dans la fonction SOMME.SI.ENS pour additionner les lignes de données correspondant à une valeur décodée dans Excel et Google Sheets.

somme si recherchev fonction principale

RECHERCHEV dans la Fonction SOMME.SI.ENS

Cet exemple résume les ventes totales de tous les codes de produit correspondant à un nom de produit donné, défini dans une table de référence séparée.

=SOMME.SI.ENS(F3:F9;E3:E9;RECHERCHEV(H3;B3:C9;2;FAUX))

somme si recherchev exemple principal fonctions imbriquees

Dans cet exemple, il n’est pas possible d’utiliser le nom du produit directement dans la fonction SOMME.SI.ENS car la table des ventes ne contient que des codes de produit. Nous devons convertir le nom en code pour calculer correctement le total des ventes . <

Nous allons décomposer et examiner la formule en plusieurs étapes.

Fonction SOMME.SI.ENS

Si nous connaissons le code produit (« T1 »), nous pouvons simplement utiliser la fonction SOMME.SI.ENS :

=SOMME.SI.ENS(F3:F9;E3:E9;"T1")

somme si recherchev fonction imbriquees etape 1

Cette formule additionne toutes les ventes correspondant au code « T1 ».

Fonction RECHERCHEV

Toutefois, si le code produit ne fournit pas suffisamment d’informations pour rendre le résumé utile, nous devons permettre l’utilisation d’un nom de produit à la place. Nous pouvons utiliser la fonction RECHERCHEV pour transformer le nom (« Table ») en son code :

=RECHERCHEV("Table";B3:C9;2;FAUX)

somme si recherchev fonction imbriquees etape 2

Cette formule trouve « Table » dans la plage de données de recherche de code produit et le fait correspondre à la valeur de la deuxième colonne de cette plage (« T1 »). Nous utilisons FAUX dans la fonction RECHERCHEV pour indiquer que nous recherchons une correspondance exacte.

Utilisation de RECHERCHEV dans SOMME.SI.ENS – Références de Cellule

Maintenant que nous avons montré comment additionner les ventes par code et comment rechercher le code par nom, nous combinons ces étapes en une seule formule.

Tout d’abord, remplacez » Table » dans la fonction RECHERCHEV par sa référence de cellule (H3).

RECHERCHEV(H3;B3:C9;2;FAUX)

L’entrée de la fonction RECHERCHEV est » Table « , et la sortie est » T1 « . Nous pouvons donc remplacer » T1 » dans la fonction SOMME.SI.ENS par la fonction RECHERCHEV pour obtenir notre formule finale :

=SOMME.SI.ENS(F3:F9;E3:E9;RECHERCHEV(H3;B3:C9;2;FAUX))

SUMIFS VLOOKUP

Verrouillage des Références de Cellule

Pour faciliter la lecture de nos formules, nous avons présenté les formules sans les références de cellule verrouillées :

=SOMME.SI.ENS(F3:F9;E3:E9;RECHERCHEV(H3;B3:C9;2;FAUX))

Mais ces formules ne fonctionneront pas correctement lorsqu’elles seront copiées et collées ailleurs dans votre fichier. Vous devez plutôt utiliser des références de cellules verrouillées comme ceci :

=SOMME.SI.ENS($F$3:$F$9;$E$3:$E$9;RECHERCHEV(H3;$B$3:$C$9;2;FAUX))

Lisez notre article sur le verrouillage des références de cellule pour en savoir plus.

Somme Si en Utilisant RECHERCHEV dans Google Sheets

Ces formules fonctionnent exactement de la même manière dans Google Sheets et dans Excel.

somme si recherchev google sheets