XLOOKUP – 여러 기준 적용하여 사용하기

이 튜토리얼에서는 Excel에서 여러 기준을 사용하여 XLOOKUP을 수행하는 방법을 설명합니다. 사용 중인 Excel 버전이 XLOOKUP을 지원하지 않는 경우 VLOOKUP을 사용하는 방법을 참조하세요.

 

XLOOKUP 기준 값 묶어서 조회하기

여러 기준 XLOOKUP을 수행하는 일반적인 방법 중 하나는 모든 기준을 하나의 조회 값으로 묶고 해당 조회 열들을 하나의 조회 배열로 묶는 것입니다.

=XLOOKUP(F3&G3,B3:B7&C3:C7,D3:D7)

수식을 자세히 살펴보겠습니다:

조회 열 묶기

먼저 조회 열들을 묶어서 모든 기준을 동시에 조회할 수 있는 고유 ID 배열을 만듭니다.

=B3&C3

기준 값 묶기

다음으로, 기준 값들에 대해서도 동일한 작업을 수행하여 새 기준 값을 만듭니다.

=F3&G3

XLOOKUP 함수

마지막으로, 새 조회 값과 조회 배열을 XLOOKUP 함수에 적용합니다.

=XLOOKUP(K3,I3:I7,D3:D7)

이 모든 것을 합치면 원래의 수식이 됩니다:

=XLOOKUP(F3&G3,B3:B7&C3:C7,D3:D7)

 

XLOOKUP 불리언 표현식을 활용하여 여러 기준 적용하기

또 다른 방법은 해당 조회 열에 대해 기준을 검사하는 불리언 표현식을 만드는 것입니다.

=XLOOKUP(1,(B3:B7=F3)*(C3:C7=G3),D3:D7)

수식을 자세히 살펴보겠습니다:

불리언 표현식

F먼저 논리 연산자(예: =,<,>)를 사용하여 해당 열에 적절한 기준을 적용해 보겠습니다.

첫 번째 기준(예: 학생 ID)부터 시작하겠습니다.

=B3=$F$3

다른 기준(예: Subject)에 대해 이 단계를 반복합니다.

=C3=$G$3

배열 간 AND 논리함수

다음으로, TRUE가 1이고 FALSE가 0인 불리언 배열을 곱하여 AND 함수와 동일한 계산을 수행합니다.

=I3*J3

참고: AND 함수는 집계 함수(여러개의 입력값으로 하나의 출력값을 반환하는 함수)입니다. 따라서 배열 계산에는 사용할 수 없습니다.

 

XLOOKUP 함수

다음으로 배열 간 AND 논리함수의 결과에서 1을 검색합니다.

=XLOOKUP(1,K3:K7,D3:D7)

모든 수식을 결합하면 원래 수식이 됩니다:

=XLOOKUP(1,(B3:B7=F3)*(C3:C7=G3),D3:D7)