Extrair a Última Palavra no Excel e no Google Planilhas
Este tutorial vai demonstrar como extrair a última palavra de uma célula no Excel e no Google Planilhas.
Extrair a Última Palavra
Se quisermos extrair a primeira palavra de uma célula poderíamos simplesmente usar a função PROCURAR para encontrar o primeiro espaço e a função ESQUERDA para extrair a palavra antes do espaço.
Infelizmente o Excel não tem uma função PROCURAR inversa, portanto, precisaremos desenvolver uma solução diferente:
- Use a Função SUBSTITUIR para substituir os espaços entre as palavras por um grande número (n) de espaços.
- Use a função DIREITA para calcular o número n correto de espaços. (Isso incluirá nossa palavra, bem como um número de espaços adicionais)
- Use a função ARRUMAR para cortar os espaços extras, deixando apenas a última palavra.
Aqui está a fórmula que usaremos:
=ARRUMAR(DIREITA(SUBSTITUIR(B6;" ";REPT(" ";10));10))
Observe que, neste exemplo, escolhemos n=10. Esse número é muito pequeno: a célula C6 não contém a última palavra completa porque a palavra tem 15 caracteres.
Escolhemos um número pequeno para fins de demonstração, mas recomendamos que você use um número muito maior (por exemplo, 99) ou use a fórmula versátil encontrada no final deste tutorial.
Agora vamos examinar a fórmula:
Função REPT
A função REPT repete um caractere (n) número de vezes. Essa fórmula gerará 10 espaços:
=REPT(" ";10)Aqui, para mostrar como essa função funcionará, substituímos os espaços em branco por traços (-):
Função SUBSTITUIR
A função SUBSTITUIR localiza todos os espaços em branco na cadeia de texto e substitui os espaços em branco por 10 espaços.
=SUBSTITUIR(B3;" ";C3)
Função DIREITA
A função DIREITA extrai somente os últimos caracteres da célula (10 no exemplo):
=DIREITA(D3;10)
Função ARRUMAR
A função ARRUMAR remove todos os espaços iniciais e finais do texto e retorna apenas a última palavra:
=ARRUMAR(E3)
Fórmula Versátil
Em vez de definir o número (n), você pode usar a função NÚM.CARACT para calcular n como o número de caracteres na célula. Essa fórmula funcionará independentemente do tamanho da última palavra.
=ARRUMAR(DIREITA(SUBSTITUIR(B3;" ";REPT(" ";NÚM.CARACT(B3)));NÚM.CARACT(B3)))
Extrair a Última Palavra no Google Planilhas
A fórmula para extrair a última palavra de um texto funciona exatamente da mesma forma no Google Planilhas e no Excel:
